Kevään 2011 pitkän matematiikan ylioppilastehtävien ratkaisut Mathematicalla
Simo K. Kivelä / 8.7.2011

Tehtävä 1

a)

Yhtälö ratkaistaan yleensä Solve-funktiolla:

Solve[2/x==3/(x-2),x]

b)

Joissakin tapauksissa täydellisempi ratkaisu saadaan Reduce-funktiolla:

Reduce[x^2-2≤x,x]

c)

Tässä tapauksessa Solve on parempi, sillä Reduce ottaisi huomioon mahdollisuuden, että x on kompleksinen:

Solve[Abs[3/2 x-6]==6,x]

Tehtävä 2

a)

Osakkeen arvo aluksi:

a=35.50

Noussut arvo:

b=a+12/100 a

Laskenut arvo:

c=b-10/100 b

Nousuprosentti muutosten jälkeen:

100 (c-a)/a

b)

Pisteet:

p1={-2,1}

p2={5,-3}

Kulmakertoimeen poimitaan koordinaatit indeksimerkintää käyttäen:

k=(p1[[2]]-p2[[2]])/(p1[[1]]-p2[[1]])

c)

Laskenta kahdessa vaiheessa:

p=5 Log[2]-Log[8]//Simplify

E^p

Tehtävä 3

Määritellään aluksi funktiot:

f[x_]=x E^(-x^2)

g[x_]=2 E^(-x^2)

Ja sitten laskut:

a)

Solve[f[x]==g[x],x]

b)

f'[1]

c)

Integrate[f[x],{x,0,1}]

Tehtävä 4

Määritellään funktio, poistetaan aiemmin käytetyt muuttujat a, b ja c  ja määritellään polynomi:

f[x_]=2^x

Remove[a,b,c]

p[x_]=a x^2+b x+c

Muodostetaan vaatimusten mukainen yhtälöryhmä ja ratkaistaan se (/. on sijoitusoperaattori, joka edellä olevaan lausekkeeseen sijoittaa esitetyt arvot; samalla kertaa voidaan tehdä useita sijoituksia):

rtk=Solve[f[x]==p[x]/.{{x->0},{x->1},{x->2}},{a,b,c}]

Sijoitetaan arvot (yhtälön ratkaisuista ensimmäinen ja ainoa) polynomiin:

p[x]/.First[rtk]

Tehtävä 5

Määritellään polynomi ja ratkaistaan derivaatan nollakohdat:

p[x_]=x (x+3) (5-x)

rtk=Solve[p'[x]==0,x]

Sijoitetaan polynomiin tarkasteluväliin kuuluva nollakohta ja välin päätepisteet:

p[x]/.{rtk[[2]],{x->-1},{x->5}}

Saaduista arvoista suurin on maksimi ja pienin minimi, siis 36 ja -12. Lopuksi kuvaaja:

Plot[p[x],{x,-1,5},GridLines->Automatic]

Tehtävä 6

Lasketaan todennäköisyydet taulukkoon binomikertoimien avulla:

pr=Table[Binomial[3,k] Binomial[7,3-k]/Binomial[10,3],{k,0,3}]

Näiden summa on 1, kuten pitääkin:

Apply[Plus,pr]

Numeeriset arvot todennäköisyyksille:

pr//N

Tehtävä 7

Jos laatat asetetaan kiinni toisiinsa, muodostuu neljäkäs symmetriasyistä. Toinen sivun pituus on a=1:

a=1

Toinen sivun pituus olkoon x. Leijan toinen lävistäjä jakaa sen kahteen kolmioon, joissa lävistäjän vastaisena kulmana on toisaalta 72°:n, toisaalta 144°:n kulma. Lävistäjän pituus voidaan kosinilausetta käyttäen muodostaa kumpaankin kolmioon pohjautuen, jolloin saadaan yhtälö luvulle x. Tämä ratkaistaan:

rtk=Solve[a^2+a^2-2 a a Cos[144 Degree]==x^2+x^2-2 x x Cos[72 Degree],x]

Sivun pituus on positiivinen ratkaisu, joka voidan vielä sieventää:

b=x/.rtk[[2]]//FullSimplify

Numeerinen arvo:

b//N

Laattojen alat sinilauseen avulla (kumpikin muodostuu kahdesta kolmiosta):

leijanAla=a b Sin[72 Degree]//FullSimplify

leijanAla//N

nuolenAla=a b Sin[36 Degree]//FullSimplify

nuolenAla//N

Tehtävä 8

Muodostetaan vektorit:

a={4,-5,3}

b={2,1,-2}

u=t b

v={x,y,z}

Muodostetaan vektoreita koskevat ehdot ja ratkaistaan näistä tuntemattomat kertoimet:

rtk=Solve[{a==u+v,b.v==0},{x,y,z,t}]

Sijoitetaan saadut arvot vektoreihin u ja v:

{u,v}/.First[rtk]

Tehtävä 9

Lukujonon määritelmä muodostaa differenssiyhtälön alkuehtoineen. Tämä voidaan ratkaista funtkiolla RSolve:

rtk=RSolve[{a[1]==5/4,a[n]==-3/4 a[n-1]},a[n],n]

Rakaisun avulla voidaan määritellä lukujono eksplisiittisesti Mathematicalle (hieman tautologista!):

a[n_]=a[n]/.First[rtk]

a[2]

a[100]

Sarjan summa:

Sum[a[n],{n,1,Infinity}]

Tehtävä 10

Poistetaan funktion f aiempi määrittely ja määritellään funktio g:

Remove[f]

g[x_]=f[x]+Sin[x]

Pinta-ala saadaan integraalista:

Integrate[Abs[f[x]-g[x]],{x,0,2 Pi}]

Tehtävä 11

a)

Määritellään funktio paloittain:

f[x_]=Piecewise[{{a x^2,x≤-1},{x^2/(1+x^2),x>-1}}]

Jotta funktio olisi kaikkialla jatkuva, sen on oltava jatkuva kohdassa x=-1 (muualla jatkuvuus on ongelmatonta). Vaaditaan, että vasemman- ja oikeanpuolinen raja-arvo ko. kohdassa ovat samat, jolloin saadaan arvo kertoimelle a:

vasen=Limit[f[x],x->-1,Direction->1]

oikea=Limit[f[x],x->-1,Direction->-1]

rtk=Solve[vasen==oikea,a]

b)

Määritellään tätä a:n arvoa vastaava funktio g ja lasketaan sen derivaatta:

g[x_]=f[x]/.rtk[[1]]

g'[x]

Derivoituvuus on siis selvää muualla paitsi pisteessä x=-1. Erotusosamäärän toispuoliset raja-arvot tässä pisteessä:

dvasen=Limit[(g[-1+h]-g[-1])/h,h->0,Direction->1]

doikea=Limit[(g[-1+h]-g[-1])/h,h->0,Direction->-1]

Nämä ovat eri suuria, joten funktio ei ole derivoituva kohdassa x=-1.

c)

Raja-arvo äärettömyydessä:

Limit[f[x],x->Infinity]

Tehtävä 12

Funktio Mod antaa jakolaskun jakojäännöksen. Koska tämä on 0, luku on jaollinen viidellä:

Mod[46^78+89^67,5]

Tehtävä 13

Funktio Factor jakaa polynomin kokonaislukukertoimisiin tekijöihin:

Factor[2 x^4-x^3+x^2-x-1]

Tehtävä 14

Muodostetaan funktiot f ja g ja niiden erotus h:

f[x_]=Cos[x]

g[x_]=1-x^2/2

h[x_]=f[x]-g[x]

a) ja b)

Lasketaan funktion h ensimmäinen ja toinen derivaatta sekä h:n ja sen derivaatan arvo origossa:

h[0]

h'[x]

h'[0]

h''[x]

Koska h''(x)≥0 ja =0 vain yksittäisissä pisteissä, h' on kasvava. Koska h'(0)=0, on h'(x)<0, kun x<0 ja h'(x)>0, kun x>0. Tällöin h on vähenevä, kun x<0, ja kasvava, kun x>0. Koska h(0)=0, on h(x)≥0 ja ainoa nollakohta on x=0.

Kuvaajat (h punainen, h' vihreä, h'' sininen):

Plot[Tooltip[{h[x],h'[x],h''[x]}],{x,-Pi,Pi},PlotStyle->{{Red,Thick},{Green,Thick},{Blue,Thick}}]

c)

Maksimiarvo päätepisteissä:

max={h[Pi],h[-Pi]}

max//N

d)

Väliin jäävän alueen pinta-ala:

Integrate[h[x],{x,-Pi,Pi}]

Tehtävä 15

f[x_]=x^2

a)

Yleinen ympyrän yhtälö:

ympyra=(x-a)^2+(y-b)^2==r^2

Vaatimus, että ympyrä kulkee pisteiden O, A ja B kautta:

ehdot=Table[ympyra/.{x->u,y->f[u]},{u,{0,-t,t}}]

Ratkaistaan ehdoista kertoimet r, a ja b (t:n funktioina):

kertoimet=Solve[ehdot,{a,b,r}]

Valitaan positiivien r:

r[t_]=r/.kertoimet[[2]]

b)

Raja-ympyrän säde raja-arvona:

r0=Limit[r[t],t->0]

c)

Raja-ympyrän yhtälö:

ymp0=ympyra/.kertoimet[[2]]/.t->0

Ratkaistaan tästä y ja valitaan se lauseke, joka antaa alapuolisen kaaren:

rtk=Solve[ymp0,y]

g[x_]=y/.rtk[[1]]

d)

Toiset derivaatat:

f''[0]

g''[0]

Kuvio:

Plot[{f[x],g[x]},{x,-1,1}]