linkmp.nb

Vakiokertoimisen lineaariyhtälön karakteristisen yhtälön kompleksiset juuret

Tarkastelun kohteena olkoon kertalukua $n$ oleva vakiokertoiminen homogeeninen differentiaaliyhtälö:

In[1]:=

$n = 3$

Out[1]=

$3$

In[2]:=

$diffyht = Sum [a_{k} D [y [x], {x, k}], {k, 0, n}] == 0$

Out[2]=

$a_{0} y [x] + a_{1} y^{'} [x] + a_{2} y^{′′} [x] + a_{3} y^{(3)} [x] ⩵ 0$

Tämän karakteristinen yhtälö saadaan sijoittamalla yhtälöön yrite $y = ⅇ^{r x}$ ja jakamalla sijoittamisen jälkeen eksponenttitekijä pois. Samaan tulokseen päästään korvaamalla differentiaaliyhtälössä derivaatat vastaavilla muuttujan $r$ potensseilla:

In[3]:=

$karaktyht = diffyht /. Table [D [y [x], {x, k}] -> r^k, {k, 0, n}]$

Out[3]=

$a_{0} + r a_{1} + r^{2} a_{2} + r^{3} a_{3} ⩵ 0$

Kyseessä on polynomiyhtälö, jonka juuret $r_{1}$ , $r_{2}$ jne. antavat differentiaaliyhtälön perusratkaisut $y = ⅇ^{r_{1} x}$ , $y = ⅇ^{r_{2} x}$ jne. Oletetaan, että yhtälöllä on kompleksinen juuripari $r_{1} = α + β ⅈ$ , $r_{2} = α - β ⅈ$ , ja pyritään osoittamaan, että tällöin vastaaviksi perusratkaisuiksi kelpaavat $ⅇ^{α x} \sin (β x)$ ja $ⅇ^{α x} \cos (β x)$ . Koska $r_{1} = α + β ⅈ$ ja $r_{2} = α - β ⅈ$ ovat juuria, seuraavat ehdot toteutuvat:

In[4]:=

$komplehdot = ComplexExpand [{karaktyht /. r -> α + ⅈ β, karaktyht /. r -> α - ⅈ β}]$

Out[4]=

${a_{0} + α a_{1} + α^{2} a_{2} - β^{2} a_{2} + α^{3} a_{3} - 3 α β^{2} a_{3} + ⅈ (β a_{1} + 2 α β a_{2} + 3 α^{2} β a_{3} - β^{3} a_{3}) ⩵ 0, a_{0} + α a_{1} + α^{2} a_{2} - β^{2} a_{2} + α^{3} a_{3} - 3 α β^{2} a_{3} + ⅈ (- β a_{1} - 2 α β a_{2} - 3 α^{2} β a_{3} + β^{3} a_{3}) ⩵ 0}$

Yhtälöissä esiintyvät vakiot ovat kaikki reaalisia, jolloin kahdesta kompleksisesta ehdosta saadaan periaatteessa neljä reaalista ehtoa asettamalla kummankin reaali- ja imaginaariosa erikseen $= 0$ . Erilaisia ehtoja saadaan kuitenkin vain kaksi, kuten pitääkin: Jos nimittäin reaalikertoimisella polynomiyhtälöllä on juurena $α + β ⅈ$ , myös liittoluku on juuri. Reaalisten ehtojen esiin poimiminen on yksinkertaisinta tehdä hiirellä. Se voidaan tehdä myös Mathematican keinoin. Tämä on hieman monivaiheista, koska Mathematica kohtelee muuttujia normaalisti kompleksisina ja tämän johdosta kertoimet on erikseen määriteltävä reaalisiksi määreellä Element[muuttujat,Reals]. Merkintä [[1]] viittaa listan ensimmäiseen elementtiin, ts. edelliseen kahdesta yhtälöstä.

In[5]:=

$muuttujat = Flatten [{Table [a_{k}, {k, 0, n}], α, β}]$

Out[5]=

${a_{0}, a_{1}, a_{2}, a_{3}, α, β}$

In[6]:=

$reaaliosaehdot = Simplify [Map [Re, komplehdot, {2}], Element [muuttujat, Reals]]$

Out[6]=

${a_{0} + α (a_{1} + α (a_{2} + α a_{3})) ⩵ β^{2} (a_{2} + 3 α a_{3}), a_{0} + α (a_{1} + α (a_{2} + α a_{3})) ⩵ β^{2} (a_{2} + 3 α a_{3})}$

In[7]:=

$imagosaehdot = Simplify [Map [Im, komplehdot, {2}], Element [muuttujat, Reals]]$

Out[7]=

${β (a_{1} + 2 α a_{2} + (3 α^{2} - β^{2}) a_{3}) ⩵ 0, β (a_{1} + 2 α a_{2} + (3 α^{2} - β^{2}) a_{3}) ⩵ 0}$

In[8]:=

$ehdot = {reaaliosaehdot [[1]], imagosaehdot [[1]]}$

Out[8]=

${a_{0} + α (a_{1} + α (a_{2} + α a_{3})) ⩵ β^{2} (a_{2} + 3 α a_{3}), β (a_{1} + 2 α a_{2} + (3 α^{2} - β^{2}) a_{3}) ⩵ 0}$

Sijoitetaan tutkittavat perusratkaisut differentiaaliyhtälöön:

In[9]:=

$sij = {diffyht /. y -> Function [x, Exp [α x] Sin [β x]], diffyht /. y -> Function [x, Exp [α x] Cos [β x]]}$

Out[9]=

${ⅇ^{x α} Sin [x β] a_{0} + (ⅇ^{x α} β Cos [x β] + ⅇ^{x α} α Sin [x β]) a_{1} + (2 ⅇ^{x α} α β Cos [x β] + ⅇ^{x α} α^{2} Sin [x β] - ⅇ^{x α} β^{2} Sin [x β]) a_{2} + (3 ⅇ^{x α} α^{2} β Cos [x β] - ⅇ^{x α} β^{3} Cos [x β] + ⅇ^{x α} α^{3} Sin [x β] - 3 ⅇ^{x α} α β^{2} Sin [x β]) a_{3} ⩵ 0, ⅇ^{x α} Cos [x β] a_{0} + (ⅇ^{x α} α Cos [x β] - ⅇ^{x α} β Sin [x β]) a_{1} + (ⅇ^{x α} α^{2} Cos [x β] - ⅇ^{x α} β^{2} Cos [x β] - 2 ⅇ^{x α} α β Sin [x β]) a_{2} + (ⅇ^{x α} α^{3} Cos [x β] - 3 ⅇ^{x α} α β^{2} Cos [x β] - 3 ⅇ^{x α} α^{2} β Sin [x β] + ⅇ^{x α} β^{3} Sin [x β]) a_{3} ⩵ 0}$

Ongelmana on, toteutuvatko nämä yhtälöt, kun oletetaan, että $α$ ja $β$ toteuttavat edellä johdetut ehdot:

In[10]:=

$Simplify [sij, ehdot]$

Out[10]=

${True, True}$

Molemmat yhtälöt näyttävät olevan tosia, ja vastaavat perusratkaisut siis todella ovat $ⅇ^{α x} \sin (β x)$ ja $ⅇ^{α x} \cos (β x)$ .

Symbolisissa laskentajärjestelmissä kuten Mathematicassa on suhteellisen hyvät työkalut (usean muuttujan) polynomiehtojen käsittelyyn; taustalla ovat ns. Gröbnerin kannat. Probleeman monimutkaistuessa laskennan raskaus kuitenkin kasvaa nopeasti.

Kompleksisten juurten tapausta voidaan käsitellä myös toisin. Koska kompleksiluvut toteuttavat samanlaiset laskusäännöt (derivointisäännöt mukaanluettuina) kuin reaaliluvutkin, voidaan ajatella, että kirjoitetaan differentiaaliyhtälön yleinen ratkaisu kompleksisten eksponenttifunktioiden avulla:

In[11]:=

$komplratk = C [1] Exp [(α + ⅈ β) x] + C [2] Exp [(α - ⅈ β) x]$

Out[11]=

$ⅇ^{x (α + ⅈ β)} C [1] + ⅇ^{x (α - ⅈ β)} C [2]$

Tämä kehitetään käyttäen eksponenttifunktion laskusääntöä $ⅇ^{x + y} = ⅇ^{x} e^{y}$ , joka on voimassa myös kompleksitapauksessa, ja sen jälkeen sovelletaan Eulerin kaavaa $ⅇ^{ⅈ u} = \cos u + ⅈ \sin u$ . Laskun voi tehdä käsin tai käyttämällä sopivaa Mathematican funktiota:

In[12]:=

$trigratk = ComplexExpand [komplratk]$

Out[12]=

$ⅇ^{x α} C [1] Cos [x β] + ⅇ^{x α} C [2] Cos [x β] + ⅈ (ⅇ^{x α} C [1] Sin [x β] - ⅇ^{x α} C [2] Sin [x β])$

Tämä todellakin näyttää sisältävän haluttua muotoa $ⅇ^{α x} \sin (β x)$ ja $ⅇ^{α x} \cos (β x)$ olevia termejä. Näiden kertoimet ovat

In[13]:=

$sinkerroin = Coefficient [trigratk, Exp [α x] Sin [β x]]$

Out[13]=

$ⅈ C [1] - ⅈ C [2]$

In[14]:=

$coskerroin = Coefficient [trigratk, Exp [α x] Cos [β x]]$

Out[14]=

$C [1] + C [2]$

Ratkaisu voidaan sieventää antamalla näille kertoimille nimet C[3] ja C[4]:

In[15]:=

$uudetvakiot = Solve [{sinkerroin ⩵ C [3], coskerroin ⩵ C [4]}, {C [1], C [2]}]$

Out[15]=

${{C [1] \to - \frac{1}{2} ⅈ (C [3] + ⅈ C [4]), C [2] \to \frac{1}{2} ⅈ (C [3] - ⅈ C [4])}}$

In[16]:=

$trigratk /. First [uudetvakiot] // Simplify$

Out[16]=

$ⅇ^{x α} (C [4] Cos [x β] + C [3] Sin [x β])$

C[1] ja C[2] sekä toisaalta C[3] ja C[4] ovat symmetrisessä asemassa. Jos kumpi tahansa pari valitaan mielivaltaisesti, toinen pari määräytyy.

Linkkejä

vakiokertoiminen homogeeniyhtälö

SKK 30.04.2001

Created by Mathematica (July 21, 2004)