srjsym.nb

Sarjaratkaisun etsiminen Mathematicalla

Olkoon tarkasteltavana ensimmäisen kertaluvun differentiaaliyhtälö:

In[1]:=

$diffyht = y' [x] == 1 + y [x]^2$

Out[1]=

$y^{'} [x] ⩵ 1 + {y [x]}^{2}$

Tälle pyritään etsimään sarjaratkaisu origokeskisenä potenssisarjana. Tavoitteena on laskea sarjan termien kertoimet $n$ -asteiseen termiin saakka:

In[2]:=

$n = 10$

Out[2]=

$10$

Tarvittava potenssisarjamuotoinen yrite jäännöstermeineen on

In[3]:=

$yrite := Function [x, Sum [a_{k} x^k, {k, 0, n}] + O [x]^(n + 1)]$

Tämä on esitetty funktiona eikä lausekkeena, jotta yhtälöön sijoitettaessa myös derivaatta saadaan sijoitetuksi:

In[4]:=

$sarjayht = diffyht /. y -> yrite$

$Series :: sbyc : Division by a series with no coefficients in \frac{1}{{O [x]}^{1}} . More…$

Out[4]=

$a_{1} + 2 a_{2} x + 3 a_{3} x^{2} + 4 a_{4} x^{3} + 5 a_{5} x^{4} + 6 a_{6} x^{5} + 7 a_{7} x^{6} + 8 a_{8} x^{7} + 9 a_{9} x^{8} + 10 a_{10} x^{9} + {O [x]}^{10} ⩵ (1 + a_{0}^{2}) + 2 a_{0} a_{1} x + (a_{1}^{2} + 2 a_{0} a_{2}) x^{2} + (2 a_{1} a_{2} + 2 a_{0} a_{3}) x^{3} + (a_{2}^{2} + 2 a_{1} a_{3} + 2 a_{0} a_{4}) x^{4} + (2 a_{2} a_{3} + 2 a_{1} a_{4} + 2 a_{0} a_{5}) x^{5} + (a_{3}^{2} + 2 a_{2} a_{4} + 2 a_{1} a_{5} + 2 a_{0} a_{6}) x^{6} + (2 a_{3} a_{4} + 2 a_{2} a_{5} + 2 a_{1} a_{6} + 2 a_{0} a_{7}) x^{7} + (a_{4}^{2} + 2 a_{3} a_{5} + 2 a_{2} a_{6} + 2 a_{1} a_{7} + 2 a_{0} a_{8}) x^{8} + (2 a_{4} a_{5} + 2 a_{3} a_{6} + 2 a_{2} a_{7} + 2 a_{1} a_{8} + 2 a_{0} a_{9}) x^{9} + (a_{5}^{2} + 2 a_{4} a_{6} + 2 a_{3} a_{7} + 2 a_{2} a_{8} + 2 a_{1} a_{9} + 2 a_{0} a_{10}) x^{10} + {O [x]}^{11}$

Yhtälön oikealla ja vasemmalla puolella on potenssisarja. Jotta nämä olisivat samat, tulee samakorkuisten potenssien kertoimien yhtälön oikealla ja vasemmalla puolella olla samat. Kertoimien välille tällöin syntyvät yhtälöt voidaan muodostaa Mathematican LogicalExpand-komennolla. Ensimmäinen yhtälö saadaan vertaamalla vakiotermien kertoimia, toinen vertaamalla ensimmäisen asteen termejä jne.

In[5]:=

$yhtalot = LogicalExpand [sarjayht]$

Out[5]=

$1 + a_{0}^{2} - a_{1} ⩵ 0 && 2 a_{0} a_{1} - 2 a_{2} ⩵ 0 && a_{1}^{2} + 2 a_{0} a_{2} - 3 a_{3} ⩵ 0 && 2 a_{1} a_{2} + 2 a_{0} a_{3} - 4 a_{4} ⩵ 0 && a_{2}^{2} + 2 a_{1} a_{3} + 2 a_{0} a_{4} - 5 a_{5} ⩵ 0 && 2 a_{2} a_{3} + 2 a_{1} a_{4} + 2 a_{0} a_{5} - 6 a_{6} ⩵ 0 && a_{3}^{2} + 2 a_{2} a_{4} + 2 a_{1} a_{5} + 2 a_{0} a_{6} - 7 a_{7} ⩵ 0 && 2 a_{3} a_{4} + 2 a_{2} a_{5} + 2 a_{1} a_{6} + 2 a_{0} a_{7} - 8 a_{8} ⩵ 0 && a_{4}^{2} + 2 a_{3} a_{5} + 2 a_{2} a_{6} + 2 a_{1} a_{7} + 2 a_{0} a_{8} - 9 a_{9} ⩵ 0 && 2 a_{4} a_{5} + 2 a_{3} a_{6} + 2 a_{2} a_{7} + 2 a_{1} a_{8} + 2 a_{0} a_{9} - 10 a_{10} ⩵ 0$

Tuloksena on rekursiivinen epälineaarinen yhtälöryhmä: ensimmäisestä yhtälöstä voidaan ratkaista $a_{1}$ , jos $a_{0}$ tunnetaan, toisesta tämän jälkeen $a_{2}$ , kolmannesta $a_{3}$ jne. Kokonaisuudesaan ryhmä voidaan ratkaista Solve-komennolla. Tässä jälkimmäiseksi argumentiksi pitäisi oikeastaan antaa lista yhtälöryhmän tuntemattomista, mutta oletuksena on, että ratkaisu tapahtuu kaikkien ryhmässä esiintyvien symbolien suhteen. Kaikkia tuntemattomia ei saada ratkaistuiksi, vaan muut voidaan ainoastaan lausua ensimmäisen kertoimen $a_{0}$ avulla; tästä annetaan varoitus.

In[6]:=

$ratk = Solve [yhtalot]$

$Solve :: svars : Equations may not give solutions for all \"solve\" variables. More…$

Out[6]=

${{a_{10} \to \frac{a_{0} (1382 + 14102 a_{0}^{2} + 47685 a_{0}^{4} + 72765 a_{0}^{6} + 51975 a_{0}^{8} + 14175 a_{0}^{10})}{14175}, a_{9} \to \frac{62 + 1382 a_{0}^{2} + 6360 a_{0}^{4} + 11655 a_{0}^{6} + 9450 a_{0}^{8} + 2835 a_{0}^{10}}{2835}, a_{8} \to \frac{1}{315} a_{0} (62 + 440 a_{0}^{2} + 1008 a_{0}^{4} + 945 a_{0}^{6} + 315 a_{0}^{8}), a_{7} \to \frac{1}{315} (17 + 248 a_{0}^{2} + 756 a_{0}^{4} + 840 a_{0}^{6} + 315 a_{0}^{8}), a_{6} \to \frac{1}{45} a_{0} (17 + 77 a_{0}^{2} + 105 a_{0}^{4} + 45 a_{0}^{6}), a_{5} \to \frac{1}{15} (2 + 17 a_{0}^{2} + 30 a_{0}^{4} + 15 a_{0}^{6}), a_{4} \to \frac{1}{3} a_{0} (2 + 5 a_{0}^{2} + 3 a_{0}^{4}), a_{3} \to \frac{1}{3} (1 + 4 a_{0}^{2} + 3 a_{0}^{4}), a_{2} \to a_{0} (1 + a_{0}^{2}), a_{1} \to 1 + a_{0}^{2}}}$

Sijoittamalla kertoimet yritteeseen saadaan ratkaisuna olevan potenssisarjan alkupää:

In[7]:=

$sarjaratk = yrite [x] /. First [ratk]$

Out[7]=

$a_{0} + (1 + a_{0}^{2}) x + a_{0} (1 + a_{0}^{2}) x^{2} + \frac{1}{3} (1 + 4 a_{0}^{2} + 3 a_{0}^{4}) x^{3} + \frac{1}{3} a_{0} (2 + 5 a_{0}^{2} + 3 a_{0}^{4}) x^{4} + \frac{1}{15} (2 + 17 a_{0}^{2} + 30 a_{0}^{4} + 15 a_{0}^{6}) x^{5} + \frac{1}{45} a_{0} (17 + 77 a_{0}^{2} + 105 a_{0}^{4} + 45 a_{0}^{6}) x^{6} + \frac{1}{315} (17 + 248 a_{0}^{2} + 756 a_{0}^{4} + 840 a_{0}^{6} + 315 a_{0}^{8}) x^{7} + \frac{1}{315} a_{0} (62 + 440 a_{0}^{2} + 1008 a_{0}^{4} + 945 a_{0}^{6} + 315 a_{0}^{8}) x^{8} + \frac{(62 + 1382 a_{0}^{2} + 6360 a_{0}^{4} + 11655 a_{0}^{6} + 9450 a_{0}^{8} + 2835 a_{0}^{10}) x^{9}}{2835} + \frac{a_{0} (1382 + 14102 a_{0}^{2} + 47685 a_{0}^{4} + 72765 a_{0}^{6} + 51975 a_{0}^{8} + 14175 a_{0}^{10}) x^{10}}{14175} + {O [x]}^{11}$

Tämä sisältää yhden määräämättömän vakion $a_{0}$ , kuten ensimmäisen kertaluvun differentiaaliyhtälön yleiselle ratkaisulle luonnollista onkin. Jos alkuehdoksi valitaan $y (0) = 0$ , tulee olla $a_{0} = 0$ . Vastaava yksittäisratkaisu on

In[8]:=

$yksittratk = sarjaratk /. a_{0} -> 0$

Out[8]=

$x + \frac{x^{3}}{3} + \frac{2 x^{5}}{15} + \frac{17 x^{7}}{315} + \frac{62 x^{9}}{2835} + {O [x]}^{11}$

Tämä on sama kuin funktion tan x origokeskinen Taylorin sarja:

In[9]:=

$Series [Tan [x], {x, 0, n}]$

Out[9]=

$x + \frac{x^{3}}{3} + \frac{2 x^{5}}{15} + \frac{17 x^{7}}{315} + \frac{62 x^{9}}{2835} + {O [x]}^{11}$

Näin tulee ollakin, sillä differentiaaliyhtälö on separoituva ja sen yleiseksi ratkaisuksi saadaan $y = \tan (x + C)$ :

In[10]:=

$DSolve [diffyht, y [x], x]$

Out[10]=

${{y [x] \to Tan [x + C [1]]}}$

Jotta sarjaratkaisulle voitaisiin piirtää kuvaaja, siitä on pudotettava jäännöstermi pois. Tämän tarkkaa lausekettahan ei tunneta eikä sille siis voida laskea numeerisia arvoja piirtämistä varten. Jäännöstermin poistaminen tapahtuu komennolla Normal:

In[11]:=

$poly = Normal [yksittratk]$

Out[11]=

$x + \frac{x^{3}}{3} + \frac{2 x^{5}}{15} + \frac{17 x^{7}}{315} + \frac{62 x^{9}}{2835}$

Sarjaratkaisu ja funktio tan x samassa kuvassa:

In[12]:=

$Plot [{poly, Tan [x]}, {x, 0, 1.5}]$

[Graphics:HTMLFiles/srjsym_1.gif]

Out[12]=

$⁃ Graphics ⁃$

Esitetty lasku ei anna viitteitä sarjaratkaisun suppenemisalueesta. Kokonaan muilla keinoilla voidaan osoittaa, että tangentin origokeskisen Taylorin sarjan suppenemissäde on $π / 2$ . Sarja suppenee siis vain välillä $] - π / 2, π / 2 [$ .

Haluttua termilukua $n$ voidaan edellä olevassa laskussa muuttaa ja tämän jälkeen laskea kaikki uudelleen valinnalla Evaluate Notebook valikosta Kernel/Evaluation.

Linkkejä

sarjamuotoinen yrite

SKK 30.04.2001

Created by Mathematica (July 21, 2004)