Vakioiden variointi kolmannen kertaluvun yhtälölle

Olkoon tarkasteltavana kolmannen kertaluvun lineaarinen epähomogeeninen differentiaaliyhtälö

>	diffyht:= (x-1)*diff(y(x), x$3)-x*diff(y(x), x$2)+diff(y(x), x)=exp(x^2);

$\mathrm{diffyht}:=\left(x-1\right)\left(\frac{d^3}{{dx}^3}y\left(x\right)\right)-x\left(\frac{d^2}{{dx}^2}y\left(x\right)\right)+\frac{d}{dx}y\left(x\right)=e^{\left(x^2\right)}$

Vastaava homogeeniyhtälö on

>	homogyht:= lhs(diffyht)=0;

$\mathrm{homogyht}:=\left(x-1\right)\left(\frac{d^3}{{dx}^3}y\left(x\right)\right)-x\left(\frac{d^2}{{dx}^2}y\left(x\right)\right)+\frac{d}{dx}y\left(x\right)=0$

Tämän ratkaisut ovat suhteellisen yksinkertaiset ja pienellä pohdiskelulla arvattavissa. Jos y :n paikalle sijoitetaan eksponenttifunktio, niin yhtälö toteutuu:

>	subs(y(x)=exp(x), homogyht): simplify(%);

$0=0$

Samoin käy, jos sijoitetaan funktio $x^2$ :

>	subs(y(x)=x^2, homogyht): simplify(%);

$0=0$

Kolmanneksi perusratkaisuksi sopii vakiofunktio, joka kaikkialla saa arvon 1:

>	subs(y(x)=1, homogyht): simplify(%);

$0=0$

Homogeeniyhtälön perusjärjestelmä on siten

>	perusjarj:= [exp(x), x^2, 1];

$\mathrm{perusjarj}:=\left[e^x,x^2,1\right]$

Linalg -paketista löytyvällä multiply -komennolla voidaan laskea matriisituloja. Kun kyseessä on kaksi vektoria, on tuloksena pistetulo. Ladataan paketti käyttöön.

>	with(linalg):

Warning, the protected names norm and trace have been redefined and unprotected

Homogeeniyhtälön yleinen ratkaisu on:

>	homogrtk:= multiply(perusjarj, [_C1, _C2, _C3]);

$\mathrm{homogrtk}:=e^x\mathrm{\_C1}+x^2\mathrm{\_C2}+\mathrm{\_C3}$

Epähomogeenisen yhtälön yksittäisratkaisu voidaan hakea vakioiden varioinnilla, jolloin yrite on

>	variot:= [u(x), v(x), w(x)];

$\mathrm{variot}:=\left[u\left(x\right),v\left(x\right),w\left(x\right)\right]$

>	yr0:= multiply(variot, perusjarj);

$\mathrm{yr0}:=u\left(x\right)e^x+v\left(x\right)x^2+w\left(x\right)$

Tämä sijoitetaan differentiaaliyhtälöön ja pyritään määrittämään sellaiset funktiot u( x ), v( x ) ja w( x ), että yhtälö toteutuu. Laskua yksinkertaistetaan kuten toisen kertaluvun yhtälön tapauksessakin asettamalla sopivia lisäehtoja. Toisen kertaluvun tapauksessa näitä on yksi, kolmannen kertaluvun tapauksessa kaksi.

Kerätään derivaatat listaksi:

>	derivaatat:= diff(variot, x);

$\mathrm{derivaatat}:=\left[\frac{d}{dx}u\left(x\right),\frac{d}{dx}v\left(x\right),\frac{d}{dx}w\left(x\right)\right]$

Muodostetaan yritteen derivaatta

>	der1:= diff(yr0, x);

$\mathrm{der1}:=\left(\frac{d}{dx}u\left(x\right)\right)e^x+u\left(x\right)e^x+\left(\frac{d}{dx}v\left(x\right)\right)x^2+2v\left(x\right)x+\frac{d}{dx}w\left(x\right)$

ja yksinkertaistetaan sitä asettamalla funktioiden u , v  ja w  derivaattoja sisältävien termien summa nollaksi:

>	termit1:= [seq(coeff(der1, derivaatat[k]), k=1..3)];

$\mathrm{termit1}:=\left[e^x,x^2,1\right]$

>	nollatermi1:= multiply(termit1, derivaatat);

$\mathrm{nollatermi1}:=\left(\frac{d}{dx}u\left(x\right)\right)e^x+\left(\frac{d}{dx}v\left(x\right)\right)x^2+\frac{d}{dx}w\left(x\right)$

Tällöin derivaatta on

>	yr1:= simplify(der1, {nollatermi1=0});

$\mathrm{yr1}:=u\left(x\right)e^x+2v\left(x\right)x$

Edellä on käytetty komentoja tarvittavan lisäehdon muodostamiseen ja derivaatan yksinkertaistamiseen. Tämä on luontevaa kirjoitettaessa ohjelmakoodia Maple lle, mutta interaktiivisessa laskennassa on yksinkertaisempaa poimia tarvittavat termit hiirellä.

Vastaavalla tavalla muodostetaan yritteen toinen derivaatta, asetetaan toinen lisäehto ja yksinkertaistetaan derivaattaa:

>	der2:= diff(yr1, x);

$\mathrm{der2}:=\left(\frac{d}{dx}u\left(x\right)\right)e^x+u\left(x\right)e^x+2\left(\frac{d}{dx}v\left(x\right)\right)x+2v\left(x\right)$

>	termit2:= [seq(coeff(der2, derivaatat[k]), k=1..3)];

$\mathrm{termit2}:=\left[e^x,2x,0\right]$

>	nollatermi2:= multiply(termit2, derivaatat);

$\mathrm{nollatermi2}:=\left(\frac{d}{dx}u\left(x\right)\right)e^x+2\left(\frac{d}{dx}v\left(x\right)\right)x$

>	yr2:= simplify(der2, {nollatermi2=0});

$\mathrm{yr2}:=u\left(x\right)e^x+2v\left(x\right)$

Yritteen kolmas derivaatta saadaan yksinkertaisesti derivoimalla; lisäehtoja ei enää aseteta:

>	yr3:= diff(yr2, x);

$\mathrm{yr3}:=\left(\frac{d}{dx}u\left(x\right)\right)e^x+u\left(x\right)e^x+2\left(\frac{d}{dx}v\left(x\right)\right)$

Yritteen derivaatat sijoitetaan differentiaaliyhtälöön, jolloin saadaan vain funktioiden u , v  ja w  derivaattoja koskeva ehto. Funktiot itse supistuvat pois; tämä on seurausta siitä, että yrite muodostetaan homogeeniyhtälön ratkaisujen avulla.

>	ehto:= subs({diff(y(x), x$3)=yr3, diff(y(x), x$2)=yr2, diff(y(x), x)=yr1, y(x)=yr0}, diffyht): factor(%);

$\left(x-1\right)\left(\left(\frac{d}{dx}u\left(x\right)\right)e^x+2\left(\frac{d}{dx}v\left(x\right)\right)\right)=e^{\left(x^2\right)}$

Derivaatat saadaan ratkaistuiksi tästä ehdosta ja aiemmin asetetuista lisäehdoista:

>	derivrtk:= solve({ehto, nollatermi1=0, nollatermi2=0}, {derivaatat[]}): simplify(%);

$\left\{\frac{d}{dx}v\left(x\right)=-\frac{1}{2}\frac{e^{\left(x^2\right)}}{-2x+1+x^2},\frac{d}{dx}w\left(x\right)=\frac{1}{2}\frac{x{e}^{\left(x^2\right)}\left(-2+x\right)}{-2x+1+x^2},\frac{d}{dx}u\left(x\right)=\frac{x{e}^{\left(x\left(x-1\right)\right)}}{-2x+1+x^2}\right\}$

Funktiot u , v  ja w  saadaan tämän jälkeen integroimalla. Selkeintä on laskea funktiot määrättyinä integraaleina alarajan ollessa mielivaltainen. Maplessa listojen integrointi tehdään integroimalla jokainen alkio erikseen map -komennon avulla:

>	integroitavat:= subs(x=t, subs(derivrtk,derivaatat)): simplify(%);

$\left[\frac{t{e}^{\left(t\left(-1+t\right)\right)}}{-2t+1+t^2},-\frac{1}{2}\frac{e^{\left(t^2\right)}}{-2t+1+t^2},\frac{1}{2}\frac{t{e}^{\left(t^2\right)}\left(-2+t\right)}{-2t+1+t^2}\right]$

>	fktrtk:= map(int, integroitavat, t=a..x): simplify(%);

$\left[\underset{a}{\overset{x}{\int }}\frac{t{e}^{\left(t\left(-1+t\right)\right)}}{-2t+1+t^2}dt,-\frac{1}{2}\underset{a}{\overset{x}{\int }}\frac{e^{\left(t^2\right)}}{-2t+1+t^2}dt,\frac{1}{2}\underset{a}{\overset{x}{\int }}\frac{t{e}^{\left(t^2\right)}\left(-2+t\right)}{-2t+1+t^2}dt\right]$

Esiintyviä integraaleja ei onnistuta lausumaan alkeisfunktioiden tai Maple n tuntemien funktioiden avulla.

Vakioiden varioinnilla on kuitenkin löydetty yksittäisratkaisu:

>	y0:= multiply(fktrtk, perusjarj): simplify(%);

$\underset{a}{\overset{x}{\int }}\frac{t{e}^{\left(t\left(-1+t\right)\right)}}{-2t+1+t^2}dt{e}^x-\frac{1}{2}\underset{a}{\overset{x}{\int }}\frac{e^{\left(t^2\right)}}{-2t+1+t^2}dt{x}^2+\frac{1}{2}\underset{a}{\overset{x}{\int }}\frac{t{e}^{\left(t^2\right)}\left(-2+t\right)}{-2t+1+t^2}dt$

Ratkaisu voidaan sijoittaa differentiaaliyhtälöön ja tarkistaa, toteutuuko yhtälö:

>	subs(y(x)=y0, diffyht): simplify(%);

$e^{\left(x^2\right)}=e^{\left(x^2\right)}$

Differentiaaliyhtälön yleinen ratkaisu on siis

>	homogrtk+y0: simplify(%);

$e^x\mathrm{\_C1}+x^2\mathrm{\_C2}+\mathrm{\_C3}+\underset{a}{\overset{x}{\int }}\frac{t{e}^{\left(t\left(-1+t\right)\right)}}{-2t+1+t^2}dt{e}^x-\frac{1}{2}\underset{a}{\overset{x}{\int }}\frac{e^{\left(t^2\right)}}{-2t+1+t^2}dt{x}^2+\frac{1}{2}\underset{a}{\overset{x}{\int }}\frac{t{e}^{\left(t^2\right)}\left(-2+t\right)}{-2t+1+t^2}dt$

>

Nimittäjien nollakohdan takia tarkastelualue on joko x  < 1 tai x  > 1. Integraalin alaraja on valittava siitä alueesta, jota tarkastellaan.

Lukija tutkikoon, miten Maple  ratkaisee edellä käsitellyn yhtälön suoraan dsolve -komennolla.

Linkkejä