Vakiokertoimisen lineaariyhtälön karakteristisen yhtälön kompleksiset juuret

Tarkastelun kohteena olkoon kertalukua n  oleva vakiokertoiminen homogeeninen differentiaaliyhtälö:

>

n:= 3;

$n:=3$

>	diffyht:= sum('a||k'*diff(y(x),[x$k]),k=0..n)=0;

$\mathrm{diffyht}:=\mathrm{a0}y\left(x\right)+\mathrm{a1}\left(\frac{d}{dx}y\left(x\right)\right)+\mathrm{a2}\left(\frac{d^2}{{dx}^2}y\left(x\right)\right)+\mathrm{a3}\left(\frac{d^3}{{dx}^3}y\left(x\right)\right)=0$

Karakteristinen yhtälö saadaan sijoittamalla yhtälöön yrite $y=e^{\mathrm{rx}}$  ja jakamalla sijoittamisen jälkeen eksponenttitekijä pois. Samaan tulokseen päästään korvaamalla differentiaaliyhtälössä derivaatat vastaavilla muuttujan r  potensseilla:

>	{seq(diff(y(x),[x$k])=r^k, k=0..n)}: karaktyht:= subs(%,diffyht);

$\mathrm{karaktyht}:=\mathrm{a0}+\mathrm{a1}r+\mathrm{a2}{r}^2+\mathrm{a3}{r}^3=0$

Kyseessä on polynomiyhtälö, jonka juuret ,  jne. antavat differentiaaliyhtälön perusratkaisut ,  jne. Oletetaan, että yhtälöllä on kompleksinen juuripari , , ja pyritään osoittamaan, että tällöin vastaaviksi perusratkaisuiksi kelpaavat $e^{\left(\alpha x\right)}\sin \left(\beta x\right)$  ja $e^{\left(\alpha x\right)}\cos \left(\beta x\right)$ . Koska  ja  ovat juuria, seuraavat ehdot toteutuvat:

>	komplehdot:= {subs(r=alpha+I*beta,karaktyht), subs(r=alpha-I*beta,karaktyht)}: simplify(%);

$\left\{\mathrm{a0}+\mathrm{a1}\alpha -\mathrm{i}\mathrm{a1}\beta +\mathrm{a2}{\alpha }^2-2i\mathrm{a2}\alpha \beta -\mathrm{a2}{\beta }^2+\mathrm{a3}{\alpha }^3-3i\mathrm{a3}{\alpha }^2\beta -3\mathrm{a3}\alpha {\beta }^2+\mathrm{i}\mathrm{a3}{\beta }^3=0,\mathrm{a0}+\mathrm{a1}\alpha +\mathrm{i}\mathrm{a1}\beta +\mathrm{a2}{\alpha }^2+2i\mathrm{a2}\alpha \beta -\mathrm{a2}{\beta }^2+\mathrm{a3}{\alpha }^3+3i\mathrm{a3}{\alpha }^2\beta -3\mathrm{a3}\alpha {\beta }^2-\mathrm{i}\mathrm{a3}{\beta }^3=0\right\}$

Yhtälöissä esiintyvät vakiot ovat kaikki reaalisia, jolloin periaatteessa kahdesta kompleksisesta ehdosta saadaan neljä reaalista ehtoa asettamalla kummankin reaali- ja imaginaariosa erikseen =0. Erilaisia ehtoja saadaan kuitenkin vain kaksi, kuten pitääkin: Jos nimittäin reaalikertoimisella polynomiyhtälöllä on juurena $\alpha +\mathrm{i}\beta$ , myös liittoluku on juuri.

Imaginaariluvun reaaliosa ja imaginaariosa saadaan poimittua komennoilla Re  ja Im . Koska Maple  ei tiedä ovatko muuttujat reaalisia vai kompleksisia, on sievennyskomennon simplify  yhteydessä käytettävä parametria assume=real , joka määrittää muuttujat reaalisiksi.

>	{Re(lhs((komplehdot[1])))=0,Im(lhs((komplehdot[1])))=0}: ehdot:= simplify(%,assume=real);

$\mathrm{ehdot}:=\left\{\mathrm{a1}\beta +2\mathrm{a2}\alpha \beta +3\mathrm{a3}{\alpha }^2\beta -\mathrm{a3}{\beta }^3=0,\mathrm{a0}+\mathrm{a1}\alpha +\mathrm{a2}{\alpha }^2-\mathrm{a2}{\beta }^2+\mathrm{a3}{\alpha }^3-3\mathrm{a3}\alpha {\beta }^2=0\right\}$

Sijoitetaan tutkittavat perusratkaisut differentiaaliyhtälöön:

>	sij:= {algsubs(y(x)=exp(alpha*x)*sin(beta*x),diffyht), algsubs(y(x)=exp(alpha*x)*cos(beta*x),diffyht)}:simplify(%);

$\left\{e^{\left(\alpha x\right)}\left(\mathrm{a2}{\alpha }^2\sin \left(\beta x\right)+2\mathrm{a2}\alpha \cos \left(\beta x\right)\beta -\mathrm{a2}\sin \left(\beta x\right){\beta }^2+\mathrm{a0}\sin \left(\beta x\right)+\mathrm{a1}\alpha \sin \left(\beta x\right)+\mathrm{a1}\cos \left(\beta x\right)\beta +\mathrm{a3}{\alpha }^3\sin \left(\beta x\right)+3\mathrm{a3}{\alpha }^2\cos \left(\beta x\right)\beta -3\mathrm{a3}\alpha \sin \left(\beta x\right){\beta }^2-\mathrm{a3}\cos \left(\beta x\right){\beta }^3\right)=0,e^{\left(\alpha x\right)}\left(\mathrm{a2}{\alpha }^2\cos \left(\beta x\right)-2\mathrm{a2}\alpha \sin \left(\beta x\right)\beta -\mathrm{a2}\cos \left(\beta x\right){\beta }^2+\mathrm{a0}\cos \left(\beta x\right)+\mathrm{a1}\alpha \cos \left(\beta x\right)-\mathrm{a1}\sin \left(\beta x\right)\beta +\mathrm{a3}{\alpha }^3\cos \left(\beta x\right)-3\mathrm{a3}{\alpha }^2\sin \left(\beta x\right)\beta -3\mathrm{a3}\alpha \cos \left(\beta x\right){\beta }^2+\mathrm{a3}\sin \left(\beta x\right){\beta }^3\right)=0\right\}$

Ongelmana on, toteutuvatko nämä yhtälöt, kun oletetaan, että $\alpha$  ja $\beta$  toteuttavat edellä johdetut ehdot:

>	simplify(sij,ehdot);

$\left\{0=0\right\}$

Yhälöt näyttävät olevan tosia, ja vastaavat perusratkaisut siis todella ovat $e^{\left(\alpha x\right)}\sin \left(\beta x\right)$  ja $e^{\left(\alpha x\right)}\cos \left(\beta x\right)$ .

Symbolisissa laskentajärjestelmissä kuten Maple ssa on suhteellisen hyvät työkalut (usean muuttujan) polynomiehtojen käsittelyyn; taustalla ovat ns. Gröbnerin kannat . Probleeman monimutkaistuessa laskennan raskaus kuitenkin kasvaa nopeasti.

Kompleksisten juurten tapausta voidaan käsitellä myös toisin. Koska kompleksiluvut toteuttavat samanlaiset laskusäännöt (derivointisäännöt mukaanluettuina) kuin reaaliluvutkin, voidaan ajatella, että kirjoitetaan differentiaaliyhtälön yleinen ratkaisu kompleksisten eksponenttifunktioiden avulla:

>	komplratk:= _C1*exp((alpha+I*beta)*x)+_C2*exp((alpha-I*beta)*x);

$\mathrm{komplratk}:=\mathrm{\_C1}{e}^{\left(\left(\alpha +\mathrm{i}\beta \right)x\right)}+\mathrm{\_C2}{e}^{\left(\left(\alpha -\mathrm{i}\beta \right)x\right)}$

Tämä kehitetään käyttäen eksponenttifunktion laskusääntöä $e^{\left(x+y\right)}=e^x{e}^y$ , joka on voimassa myös kompleksitapauksessa, ja sen jälkeen sovelletaan Eulerin kaavaa   $e^{\left(\mathrm{i}u\right)}=\cos \left(u\right)+\mathrm{i}\sin \left(u\right)$ . Laskun voi tehdä käsin tai käyttämällä sopivasti Maple n komentoja.

Convert -komento muuntaa lausekkeen kaikki exponenttimerkinnät trigonometrisiksi. Koska emme kuitenkaan halua muuntaa termejä, jotka sisältävät $e^{\left(\alpha x\right)}$  trigonometrisiksi, on tehtävä muunnos takaisin eksponenttimuotoon.

>	convert(komplratk,trig): trigratk:= subs(convert(exp(x*alpha),trig)=exp(x*alpha),%): expand(%);

$\mathrm{\_C1}{e}^{\left(\alpha x\right)}\cos \left(\beta x\right)+\mathrm{i}\mathrm{\_C1}{e}^{\left(\alpha x\right)}\sin \left(\beta x\right)+\mathrm{\_C2}\cosh \left(\alpha x\right)\cos \left(\beta x\right)-\mathrm{i}\mathrm{\_C2}\cosh \left(\alpha x\right)\sin \left(\beta x\right)+\mathrm{\_C2}\sinh \left(\alpha x\right)\cos \left(\beta x\right)-\mathrm{i}\mathrm{\_C2}\sinh \left(\alpha x\right)\sin \left(\beta x\right)$

Tämä todellakin näyttää sisältävän haluttua muotoa $e^{\left(\alpha x\right)}\sin \left(\beta x\right)$  ja $e^{\left(\alpha x\right)}\cos \left(\beta x\right)$  olevia termejä. Näiden kertoimet ovat

>	coeff(trigratk,sin(beta*x)): sinkerroin:=coeff(%,exp(alpha*x));

$\mathrm{sinkerroin}:=\mathrm{i}\mathrm{\_C1}$

>	coeff(trigratk,cos(beta*x)): coskerroin:=coeff(%,exp(alpha*x));

$\mathrm{coskerroin}:=\mathrm{\_C1}$

Ratkaisu voidaan sieventää antamalla näille kertoimille nimet _C3  ja _C4 :

>	simplify(trigratk,{sinkerroin=_C3,coskerroin=_C4});

$\mathrm{\_C2}\cosh \left(\alpha x\right)\cos \left(\beta x\right)-\mathrm{i}\mathrm{\_C2}\cosh \left(\alpha x\right)\sin \left(\beta x\right)+\mathrm{\_C2}\sinh \left(\alpha x\right)\cos \left(\beta x\right)-\mathrm{i}\mathrm{\_C2}\sinh \left(\alpha x\right)\sin \left(\beta x\right)+\left(e^{\left(\alpha x\right)}\cos \left(\beta x\right)+\mathrm{i}{e}^{\left(\alpha x\right)}\sin \left(\beta x\right)\right)\mathrm{\_C4}$

>

_C1  ja _C2  sekä toisaalta _C3  ja _C4  ovat symmetrisessä asemassa. Jos kumpi tahansa pari valitaan mielivaltaisesti, toinen pari määräytyy.

Linkkejä