Ensimmäisen kertaluvun yhtälö

Eulerin menetelmä alkuarvoprobleeman y ' = f( x , y ), y( ) = ,  ratkaisemiseksi voidaan ohjelmoida Maple lle eulernum -nimiseksi proseduuriksi seuraavalla tavalla (solu on ajettava, jotta mäÂäritelmä tulee voimaan):

>	eulernum:=proc(f, x0, y0, h, xend)   local kend, x, y, i;   kend:= round((xend-x0)/h);   x[0]:= x0;   y[0]:= y0;   for i from 1 to kend do     x[i]:= x[i-1]+h;     y[i]:= y[i-1]+h*f(x[i-1], y[i-1]);   od; return [seq([x[k], y[k]], k=0..kend)]; end:

Proseduurin ensimmäinen argumentti on differentiaaliyhtälön oikean puolen funktio f   Maple n funktioksi mäÂäriteltynä, kaksi seuraavaa mäÂärittävät alkuehdon, neljäs on askelpituus. Laskenta tapahtuu välillä [x0,xend] .

Proseduurin toisella rivillä lasketaan tarvittavien askelten lukumäÂärä kend . Kolmannella ja neljännellä rivillä mäÂäritelläÂän alkuarvot. For -silmukassa lasketaan numeerisen ratkaisun hilapisteet Eulerin menetelmällä. Viimeisellä rivillä palautetaan vastaus listana koottuna xy -pareiksi.

Numeerinen ratkaiseminen tapahtuu antamalla tarvittavat argumentit eulernum -funktiolle, jolloin tulokseksi saadaan lista hilapisteiden koordinaateista. Argumentit voidaan tallettaa muillekin nimille kuin funktion mäÂärittelyssä käytetyille tai antaa myös suoraan numeroina (esimerkiksi askel:= 0.1 , eulernum(f,x0,y0,askel,xend)  tai eulernum(unapply(2*x*y,x,y),0,1,0.1,2) .

>	f:= unapply(2*x*y, x, y);

>

h:= 0.1;

$h:=.1$

>

x0:= 0;

$\mathrm{x0}:=0$

>

y0:= 1;

$\mathrm{y0}:=1$

>

xend:= 2;

$\mathrm{xend}:=2$

>	eulerdata:= eulernum(f, x0, y0, h, xend);

$\mathrm{eulerdata}:=\left[\left[0,1\right],\left[.1,1.\right],\left[.2,1.02\right],\left[.3,1.0608\right],\left[.4,1.124448\right],\left[.5,1.21440384\right],\left[.6,1.335844224\right],\left[.7,1.496145531\right],\left[.8,1.705605905\right],\left[.9,1.978502850\right],\left[1.0,2.334633363\right],\left[1.1,2.801560036\right],\left[1.2,3.417903244\right],\left[1.3,4.238200023\right],\left[1.4,5.340132029\right],\left[1.5,6.835368997\right],\left[1.6,8.885979697\right],\left[1.7,11.72949320\right],\left[1.8,15.71752089\right],\left[1.9,21.37582841\right],\left[2.0,29.49864321\right]\right]$

Datan perusteella voidaan piirtäÂä kuva ratkaisua approksimoivista pisteistä.

>	eulerkuva:= plot(eulerdata, style=point): eulerkuva;

Samaan tapaan voidaan ohjelmoida parannettu Eulerin menetelmä, Rungen – Kuttan menetelmä ja Adamsin – Bashforthin menetelmä:

>

pareuler:= proc(f, x0, y0, h, xend)   local kend, x, y, i;   kend:= round((xend-x0)/h);   x[0]:= x0;   y[0]:= y0;   for i from 1 to kend do     x[i]:= x[i-1]+h;     y[i]:= y[i-1]+       h/2*(f(x[i-1], y[i-1])+         f(x[i], y[i-1]+h*f(x[i-1], y[i-1])));   od; return [seq([x[k],y[k]], k=0..kend)]; end:

>

rungekutta:= proc(f, x0, y0, h, xend)   local kend, x, y, i, k1, k2, k3, k4;   kend:= round((xend-x0)/h);   x[0]:= x0;   y[0]:= y0;   for i from 1 to kend do     x[i]:= x[i-1]+h;     k1:= h*f(x[i-1], y[i-1]);     k2:= h*f(x[i-1]+h/2, y[i-1]+k1/2);     k3:= h*f(x[i-1]+h/2, y[i-1]+k2/2);     k4:= h*f(x[i-1]+h, y[i-1]+k3);     y[i]:= y[i-1]+1/6*(k1+2*k2+2*k3+k4);   od; return [seq([x[k], y[k]], k=0..kend)]; end:

>

adamsbashforth:= proc(f, x0, y0, h, xend)   local kend, x, y, i, k1, k2, k3, k4;   kend:= round((xend-x0)/h);   x[0]:= x0;   y[0]:= y0;   for i from 1 to 3 do     x[i]:= x[i-1]+h;     k1:= h*f(x[i-1], y[i-1]);     k2:= h*f(x[i-1]+h/2, y[i-1]+k1/2);     k3:= h*f(x[i-1]+h/2, y[i-1]+k2/2);     k4:= h*f(x[i-1]+h, y[i-1]+k3);     y[i]:= y[i-1]+1/6*(k1+2*k2+2*k3+k4);   od;   for i from 4 to kend do     x[i]:= x[i-1]+h;     y[i]:= y[i-1]+h/24*(       55*f(x[i-1], y[i-1])-       59*f(x[i-2], y[i-2])+       37*f(x[i-3], y[i-3])-       9*f(x[i-4], y[i-4]))   od; return [seq([x[k], y[k]], k=0..kend)]; end:

Näiden avulla muodostetut ratkaisut ja vastaavat kuvat:

>	pareulerdata:= pareuler(f, x0, y0, h, xend);

$\mathrm{pareulerdata}:=\left[\left[0,1\right],\left[.1,1.010000000\right],\left[.2,1.040704000\right],\left[.3,1.093988045\right],\left[.4,1.173192779\right],\left[.5,1.283472900\right],\left[.6,1.432355756\right],\left[.7,1.630593793\right],\left[.8,1.893445512\right],\left[.9,2.242596864\right],\left[1.0,2.709057012\right],\left[1.1,3.337558238\right],\left[1.2,4.193308170\right],\left[1.3,5.372466428\right],\left[1.4,7.018590142\right],\left[1.5,9.348762069\right],\left[1.6,12.69561889\right],\left[1.7,17.57581479\right],\left[1.8,24.80298983\right],\left[1.9,35.67662057\right],\left[2.0,52.30192576\right]\right]$

>	pareulerkuva:= plot(pareulerdata, style=point): pareulerkuva;

>	rungekuttadata:= rungekutta(f, x0, y0, h, xend);

$\mathrm{rungekuttadata}:=\left[\left[0,1\right],\left[.1,1.010050166\right],\left[.2,1.040810769\right],\left[.3,1.094174264\right],\left[.4,1.173510813\right],\left[.5,1.284025255\right],\left[.6,1.433328994\right],\left[.7,1.632315187\right],\left[.8,1.896478467\right],\left[.9,2.247902589\right],\left[1.0,2.718270175\right],\left[1.1,3.353460191\right],\left[1.2,4.220645591\right],\left[1.3,5.419379283\right],\left[1.4,7.099124725\right],\left[1.5,9.487335476\right],\left[1.6,12.93502908\right],\left[1.7,17.99176113\right],\left[1.8,25.53067937\right],\left[1.9,36.96006234\right],\left[2.0,54.58630867\right]\right]$

>	rungekuttakuva:= plot(rungekuttadata, style=point): rungekuttakuva;

>	adamsbashforthdata:= adamsbashforth(f, x0, y0, h,xend);

$\mathrm{adamsbashforthdata}:=\left[\left[0,1\right],\left[.1,1.010050166\right],\left[.2,1.040810769\right],\left[.3,1.094174264\right],\left[.4,1.173420046\right],\left[.5,1.283764305\right],\left[.6,1.432786640\right],\left[.7,1.631313792\right],\left[.8,1.894732637\right],\left[.9,2.244948474\right],\left[1.0,2.713344710\right],\left[1.1,3.345294745\right],\left[1.2,4.207108940\right],\left[1.3,5.396852546\right],\left[1.4,7.061394527\right],\left[1.5,9.423611254\right],\left[1.6,12.82634935\right],\left[1.7,17.80440109\right],\left[1.8,25.20390923\right],\left[1.9,36.38313185\right],\left[2.0,53.55462781\right]\right]$

>	adamsbashforthkuva:= plot(adamsbashforthdata, style=point): adamsbashforthkuva;

Esimerkkinä oleva alkuarvoprobleema on myös ratkaistavissa algebrallisesti, jolloin voidaan verrata eri menetelmien tarkkuutta toisiinsa ja myös tarkkaan ratkaisuun:

>	tarkkaratkaisu:= dsolve({diff(y(x), x)=2*x*y(x), y(x0)=y0}, y(x));

$\mathrm{tarkkaratkaisu}:=y\left(x\right)=e^{\left(x^2\right)}$

>	tarkkakuva:= plot(rhs(tarkkaratkaisu), x=0..xend): tarkkakuva;

Kaikki ratkaisut samassa kuvassa:

>	with(plots):

Warning, the name changecoords has been redefined

>	display(eulerkuva, pareulerkuva, rungekuttakuva, adamsbashforthkuva, tarkkakuva);

Lopuksi eri menetelmillä saadut arvot tarkasteluvälin loppupisteessä:

>	eulerdata[-1][2], pareulerdata[-1][2], rungekuttadata[-1][2], adamsbashforthdata[-1][2], evalf(subs(x=2,rhs(tarkkaratkaisu)));

$29.49864321,52.30192576,54.58630867,53.55462781,54.59815003$

>

Edellä olevia syötteitä voi muuntaa ja tämän jälkeen ajaa koko muistikirjan yhdellä kerralla (valikko Edit  / Execute  / Worksheet ).

Linkkejä