Käyräparven kohtisuorat leikkaajat napakoordinaattitapauksessa

Esimerkki on jatkoa 'Käyräparven kohtisuorat leikkaajat' -esimerkille, jossa vastaavaa ongelmaa on tarkasteltu suorakulmaisissa koordinaateissa.

Puhdistetaan työtila:

>

restart;

Käyräparvi voidaan antaa myös napakoordinaattiesityksenä muodossa . Olkoon annettuna myös toinen käyräparvi . Ehto näiden kohtisuoralle leikkaamiselle voidaan johtaa seuraavasti:

Kummankin käyrän pisteiden suorakulmaiset koordinaatit saadaan vektoreista

>	v[1]:= [r[1](phi)*cos(phi), r[1](phi)*sin(phi)];

>	v[2]:= [r[2](phi)*cos(phi), r[2](phi)*sin(phi)];

Näissä napakulma $\phi$  on käyräparametrin asemassa. Käyrien tangenttivektorit saadaan derivoimalla käyräparametrin suhteen:

>	t[1]:= diff(v[1], phi);

>	t[2]:= diff(v[2], phi);

Käyrien leikkaamisen kohtisuoruusehto on, että tangenttivektorit ovat toisiaan vastaan kohtisuorat, ts. niiden pistetulo on = 0.

Pistetulo muodostetaan linalg -paketin multiply -komennolla.

>	with(linalg):

Warning, the protected names norm and trace have been redefined and unprotected

>	kohtisuoruusehto:= multiply(t[1], t[2])=0: simplify(%);

Ratkaisemalla tästä  saadaan:

>	ratk1:= diff(r[1](phi), phi)=solve(kohtisuoruusehto, diff(r[1](phi), phi));

Ottamalla huomioon, että leikkauspisteessä , saadaan:

>	subs({r[1](phi)=r(phi), r[2](phi)=r(phi)}, ratk1);

$\frac{d}{d\phi }r\left(\phi \right)=-\frac{{r\left(\phi \right)}^2}{\frac{d}{d\phi }r\left(\phi \right)}$

Korvausehto, joka tarvitaan johdettaessa alkuperäisen parven differentiaaliyhtälöstä kohtisuorien leikkajien differentiaaliyhtälö, on siis

Esimerkkinä olkoon käyräparven

>	parvi:= r(phi)=C*exp(k*phi);

$\mathrm{parvi}:=r\left(\phi \right)=C{e}^{\left(k\phi \right)}$

kohtisuorien leikkaajien etsiminen.

Käyräparven kuva arvolla $k=\frac{1}{2}$  voidaan piirtää plot -komennolla käyttämällä parametria coords=polar .

>	with(plots):

Warning, the name changecoords has been redefined

>	kuva1:=seq(plot(subs(k=0.5, rhs(parvi)), phi=-2..6, coords=polar), C=1..10):

>	display(kuva1, scaling=constrained, view=[-60..60, -120..30]);

Käyräparven differentiaaliyhtälön johto:

>	derivparvi:= diff(parvi,phi);

$\mathrm{derivparvi}:=\frac{d}{d\phi }r\left(\phi \right)=Ck{e}^{\left(k\phi \right)}$

>	eliminoi:= eliminate({parvi, derivparvi}, C);

$\mathrm{eliminoi}:=\left[\left\{C=\frac{r\left(\phi \right)}{e^{\left(k\phi \right)}}\right\},\left\{-\frac{d}{d\phi }r\left(\phi \right)+r\left(\phi \right)k\right\}\right]$

>	diffyht:= eliminoi[-1][]=0;

$\mathrm{diffyht}:=-\frac{d}{d\phi }r\left(\phi \right)+r\left(\phi \right)k=0$

Kohtisuorien leikkaajien differentiaaliyhtälö saadaan tekemällä alussa johdettu korvaus:

>	diffyht2:= subs(diff(r(phi), phi)=-r(phi)^2/diff(r(phi), phi), diffyht);

$\mathrm{diffyht2}:=\frac{{r\left(\phi \right)}^2}{\frac{d}{d\phi }r\left(\phi \right)}+r\left(\phi \right)k=0$

Tämän ratkaiseminen antaa kohtisuorat leikkaajat:

>	ratk2:= dsolve(diffyht2, r(phi));

Warning, it is required that the numerator of the given ODE depends on the highest derivative. Returning NULL.

$\mathrm{ratk2}:=r\left(\phi \right)=\mathrm{\_C1}{e}^{\left(-\frac{\phi }{k}\right)}$

Maple ei pidä siitä, että dsolve -komennolle annetun differentiaaliyhtälön korkein derivaatta on nimittäjässä ja antaa siksi varoituksen.

Kuva kohtisuorien leikkaajien parvesta arvolla $k=\frac{1}{2}$  ja molemmista parvista yhdessä:

>	kuva2:= seq(plot(subs(k=0.5, rhs(ratk2)), phi=-2..6, coords=polar), _C1=1..20):

>	display(kuva2, scaling=constrained, view=[-75..75, -120..30]);

>	display({kuva1,kuva2}, scaling=constrained, view=[-75..75, -120..30]);

Kuvasta voidaan ottaa osasuurennus:

>	display({kuva1, kuva2}, scaling=constrained, view=[-0..10, -5..5]);

>

Tehtäviä

Etsi napakoordinaateissa annetun käyräparven $r=C\cos \left(\phi \right)$  kohtisuorat leikkaajat. Mieti ennen piirtämistä, millaisesta käyräparvesta on kyse.

Tutki, millainen korvausehto saadaan, jos käyräparvien halutaan leikkaavan 45 asteen kulmassa. Sovella tätä sekä esimerkin alkuperäiseen käyräparveen että edellisen tehtävän parveen.

Linkkejä