Sarjaratkaisun etsiminen Maplella

Olkoon tarkasteltavana ensimmäisen kertaluvun differentiaaliyhtälö:

>	diffyht:= diff(y(x), x)=1+y(x)^2;

$\mathrm{diffyht}:=\frac{d}{dx}y\left(x\right)=1+{y\left(x\right)}^2$

Tälle pyritään etsimään sarjaratkaisu origokeskisenä potenssisarjana. Tavoitteena on laskea sarjan termien kertoimet n  -asteiseen termiin saakka:

>

n:= 10;

$n:=10$

Potenssisarjojen käsittelyä varten on Maple ssa paketti powseries .

>	with(powseries):

Tarvittava potenssisarjamuotoinen yrite on

>	powcreate(yrite(k)=a[k]): tpsform(yrite, x, n);

$a_0+a_{1}x+a_2{x}^2+a_3{x}^3+a_4{x}^4+a_5{x}^5+a_6{x}^6+a_7{x}^7+a_8{x}^8+a_9{x}^9+O\left(x^{10}\right)$

Powcreate -komennolla luodaan Maple -proseduuri, joka vastaa haluttua potenssisarjaa. Tpsform -komennolla saadaan tulostettua haluttu määrä termejä luodusta potenssisarjasta. Powseries -pakettia käytettäessä on potenssisarjojen väliset operaatiot tehtävä paketin työkaluilla. Esimerkiksi kahta powcreate -komennolla luotua potenssisarjaa ei voida kertoa keskenään operaattorilla *, vaan on käytettävä paketin komentoa multiply . Vastaavasti diff -komento ei pure potenssisarjaan vaan on käytettävä komentoa powdiff .

Sijoittamista varten on paketin työkaluilla laskettava valmiiksi alkuperäisessä differentiaaliyhtälössä esiintyvät derivointi ja toiseen potenssiin korottaminen. Tämän jälkeen potenssisarjoista muodostetaan sijoitusta varten polynomit ottamalla mukaan n ensimmäistä termiä.

>	yriteder:= powdiff(yrite): tpsform(yriteder, x, n);

$a_1+2a_{2}x+3a_3{x}^2+4a_4{x}^3+5a_5{x}^4+6a_6{x}^5+7a_7{x}^6+8a_8{x}^7+9a_9{x}^8+10a_{10}{x}^9+O\left(x^{10}\right)$

>	yritetoiseen:= multiply(yrite, yrite): tpsform(yritetoiseen, x, n);

${a_0}^2+2a_0{a}_{1}x+\left(2a_0{a}_2+{a_1}^2\right)x^2+\left(2a_0{a}_3+2a_1{a}_2\right)x^3+\left(2a_0{a}_4+2a_1{a}_3+{a_2}^2\right)x^4+\left(2a_0{a}_5+2a_1{a}_4+2a_2{a}_3\right)x^5+\left(2a_0{a}_6+2a_1{a}_5+2a_2{a}_4+{a_3}^2\right)x^6+\left(2a_0{a}_7+2a_1{a}_6+2a_2{a}_5+2a_3{a}_4\right)x^7+\left(2a_0{a}_8+2a_1{a}_7+2a_2{a}_6+2a_3{a}_5+{a_4}^2\right)x^8+\left(2a_0{a}_9+2a_1{a}_8+2a_2{a}_7+2a_3{a}_6+2a_4{a}_5\right)x^9+O\left(x^{10}\right)$

>	yritederpol:= convert(tpsform(yriteder, x, n), polynom);

>	yritetoiseenpol:= convert(tpsform(yritetoiseen, x, n), polynom);

Sijoitetaan yrite differentiaaliyhtälöön.

>	sarjayht:= yritederpol=1+yritetoiseenpol;

Yhtälön oikealla ja vasemmalla puolella on potenssisarja. Jotta nämä olisivat samat, tulee samakorkuisten potenssien kertoimien yhtälön oikealla ja vasemmalla puolella olla samat. Vähentämällä yhtälön oikea puoli vasemmasta saadaan aikaan polynomi, jonka potenssien kertoimien tulee tällöin olla 0. Poimimalla kertoimet coeffs -komennolla ja määrittelemällä ne nollaksi, saadaan yhtälöryhmä.

>	lhs(sarjayht)-rhs(sarjayht): coeffs(%, x): yhtalot:= {seq(%[i]=0, i=1..n)};

Tuloksena on rekursiivinen epälineaarinen yhtälöryhmä: ensimmäisestä yhtälöstä voidaan ratkaista , jos  tunnetaan, toisesta tämän jälkeen , kolmannesta  jne. Kokonaisuudessaan ryhmä voidaan ratkaista solve -komennolla. Tässä jälkimmäiseksi argumentiksi pitäisi oikeastaan antaa lista yhtälöryhmän tuntemattomista, mutta oletuksena on, että ratkaisu tapahtuu kaikkien ryhmässä esiintyvien symbolien suhteen. Kaikkia tuntemattomia ei saada ratkaistuiksi, vaan muut voidaan ainoastaan lausua ensimmäisen kertoimen  avulla.

>	ratk:= solve(yhtalot);

Sijoittamalla kertoimet yritteeseen saadaan ratkaisuna olevan potenssisarjan alkupää:

>	sarjaratk:= subs(ratk, tpsform(yrite, x, n+1));

$\mathrm{sarjaratk}:=a_0+\left(1+{a_0}^2\right)x+a_0\left(1+{a_0}^2\right)x^2+\left(\frac{4}{3}{a_0}^2+{a_0}^4+\frac{1}{3}\right)x^3+\left(\frac{5}{3}{a_0}^3+{a_0}^5+\frac{2}{3}{a}_0\right)x^4+\left(2{a_0}^4+{a_0}^6+\frac{17}{15}{a_0}^2+\frac{2}{15}\right)x^5+\left(\frac{7}{3}{a_0}^5+{a_0}^7+\frac{77}{45}{a_0}^3+\frac{17}{45}{a}_0\right)x^6+\left(\frac{8}{3}{a_0}^6+{a_0}^8+\frac{12}{5}{a_0}^4+\frac{248}{315}{a_0}^2+\frac{17}{315}\right)x^7+\left(3{a_0}^7+{a_0}^9+\frac{16}{5}{a_0}^5+\frac{88}{63}{a_0}^3+\frac{62}{315}{a}_0\right)x^8+\left(\frac{1382}{2835}{a_0}^2+\frac{10}{3}{a_0}^8+\frac{424}{189}{a_0}^4+\frac{37}{9}{a_0}^6+\frac{62}{2835}+{a_0}^{10}\right)x^9+\left(\frac{1382}{14175}{a}_0+\frac{14102}{14175}{a_0}^3+\frac{3179}{945}{a_0}^5+\frac{77}{15}{a_0}^7+\frac{11}{3}{a_0}^9+{a_0}^{11}\right)x^{10}+O\left(x^{11}\right)$

Tämä sisältää yhden määräämättömän vakion , kuten ensimmäisen kertaluvun differentiaaliyhtälön yleiselle ratkaisulle luonnollista onkin. Jos alkuehdoksi valitaan y (0) = 0, tulee olla . Vastaava yksittäisratkaisu on

>	yksratk:= subs(a[0]=0, sarjaratk);

$\mathrm{yksratk}:=x+\frac{1}{3}{x}^3+\frac{2}{15}{x}^5+\frac{17}{315}{x}^7+\frac{62}{2835}{x}^9+O\left(x^{11}\right)$

Tämä on sama kuin funktion tan( x ) origokeskinen Taylorin sarja:

>	series(tan(x), x, n+1);

$x+\frac{1}{3}{x}^3+\frac{2}{15}{x}^5+\frac{17}{315}{x}^7+\frac{62}{2835}{x}^9+O\left(x^{11}\right)$

Näin tulee ollakin, sillä differentiaaliyhtälö on separoituva ja sen yleiseksi ratkaisuksi saadaan y  = tan( x  + C ).

>	dsolve(diffyht, y(x));

$y\left(x\right)=\tan \left(x+\mathrm{\_C1}\right)$

Jotta sarjaratkaisulle voitaisiin piirtää kuvaaja, siitä on pudotettava jäännöstermi pois. Tämän tarkkaa lausekettahan ei tunneta eikä sille siis voida laskea numeerisia arvoja piirtämistä varten. Jäännöstermin poistaminen tapahtuu muuntamalla potenssisarja polynomiksi komennolla convert .

>	poly:= convert(yksratk, polynom);

$\mathrm{poly}:=x+\frac{1}{3}{x}^3+\frac{2}{15}{x}^5+\frac{17}{315}{x}^7+\frac{62}{2835}{x}^9$

Sarjaratkaisu ja funktio tan( x ) samassa kuvassa:

>	plot({poly, tan(x)}, x=0..1.5);

Esitetty lasku ei anna viitteitä sarjaratkaisun suppenemisalueesta. Kokonaan muilla keinoilla voidaan osoittaa, että tangentin origokeskisen Taylorin sarjan suppenemissäde on $\frac{1}{2}\pi$ . Sarja suppenee siis vain välillä ] $-\frac{1}{2}\pi ,\frac{1}{2}\pi$ [.

Haluttua termilukua  voidaan edellä olevassa laskussa muuttaa ja tämän jälkeen laskea kaikki uudelleen valinnalla Evaluate Notebook valikosta Kernel/Evaluation.

Ratkaisu suoraan dsolve-komennolla

Maple n dsolve -komennolla on mahdollista laskea suoraan ratkaisuja, jotka ovat Taylorin sarjoja. Tällöin käytetään parametria type=series .

Esimerkkinä edellä johdettu sarjaratkaisu suoraan dsolve -komennolla:

>	Order:=10: dsolve({diffyht, y(0)=0}, y(x), type=series): simplify(%);

$y\left(x\right)=x+\frac{1}{3}{x}^3+\frac{2}{15}{x}^5+\frac{17}{315}{x}^7+\frac{62}{2835}{x}^9+O\left(x^{10}\right)$

>

Linkkejä