Tykillä ampuminen 1

Heittoliikkeeseen kuuluu keskeisinä tekijöinä maan vetovoima sekä ilmanvastuksen aiheuttama nopeudelle vastakkaissuuntainen voima. Näitä voimia sovelletaan myös mallinnettaessa tykin ammuksen liikerataa.

Yksinkertaisimmassa mallissa jätetään ilmanvastus huomiotta. Tällöin ammukseen vaikuttaa lähtöhetken jälkeen vain maan vetovoima , missä  on maan vetovoiman aiheuttama kiihtyvyys ja m  ammuksen massa. Kun kiihtyvyys lausutaan derivaatan avulla , saa yleinen liikeyhtälö  tällöin muodon

mistä massa m  voidaan supistaa pois.

Tarkastellaan seuraavaa ongelmaa: Mikä on oikea ampumiskulma, kun 25 metrin korkeudella sijaitsevalta tykkilavetilta ammutaan 10 kg kranaatti nopeudella 500 m/s kohti meren pinnalla olevaa maalia, jonka etäisyys on tasan 10 km?

Jaetaan yllä esitetty toisen kertaluvun differentiaaliyhtälö kahteen eri osayhtälöön, z-suuntaan ja x-suuntaan, ja ratkaistaan yhtälöt. Laskujen aluksi on syytä hävittää mahdollisista aiemmista laskuista jääneet muuttujat.

>

restart;

Määritellään differentiaaliyhtälöryhmä  ja sen tuntemattomat muuttujat.

>	ryhma:= diff(x(t), t$2)=0, diff(z(t), t$2)=-g;

$\mathrm{ryhma}:=\frac{d^2}{{dt}^2}x\left(t\right)=0,\frac{d^2}{{dt}^2}z\left(t\right)=-g$

>	muuttujat:= x(t), z(t);

$\mathrm{muuttujat}:=x\left(t\right),z\left(t\right)$

Määritellään vakiot ja alkuehto. Ammuksen lähtökulma olkoon $\theta$ . Sisällytetään ehtoon sekä ammuksen alkunopeus jaettuna nopeuskomponentteihin että lähtökorkeus.

>	g:= 9.81: m:= 10: v0:= 500:

>	alkuehto:= x(0)=0, z(0)=25, D(x)(0)=v0*cos(theta), D(z)(0)=v0*sin(theta);

$\mathrm{alkuehto}:=x\left(0\right)=0,z\left(0\right)=25,\left(x^{\prime }\right)\left(0\right)=500\cos \left(\theta \right),\left(z^{\prime }\right)\left(0\right)=500\sin \left(\theta \right)$

Ratkaistaan alkuarvoprobleema:

>	dyrtk:= dsolve({ryhma, alkuehto}, {muuttujat});

$\mathrm{dyrtk}:=\left\{z\left(t\right)=-\frac{981}{200}{t}^2+500\sin \left(\theta \right)t+25,x\left(t\right)=500\cos \left(\theta \right)t\right\}$

Ammuksen rata on paraabeli, jonka parametrimuotoinen esitys on

>	lentorata:= subs(dyrtk, [x(t), z(t)]);

$\mathrm{lentorata}:=\left[500\cos \left(\theta \right)t,-\frac{981}{200}{t}^2+500\sin \left(\theta \right)t+25\right]$

Ammuksen kokonaislentoaika ja lähtökulma saadaan ratkaisemalla yhtälöryhmä:

>	sys:= zip((x, y)->x=y, lentorata, [10000, 0]);

$\mathrm{sys}:=\left[500\cos \left(\theta \right)t=10000,-\frac{981}{200}{t}^2+500\sin \left(\theta \right)t+25=0\right]$

>	rtk:= solve({sys[]}, {t, theta});

RootOf (...) edustaa jotakin yhtälön juurta. Juuret saadaan ratkaistua allvalues -komennolla.

>	juuret:= [evalf(allvalues(rtk))];

$\mathrm{juuret}:=\left[\left\{\theta =-1.772307162,t=-99.92514551\right\},\left\{\theta =1.369285492,t=99.92514551\right\},\left\{\theta =-2.942581815,t=-20.40269588\right\},\left\{\theta =.1990108389,t=20.40269588\right\}\right]$

Vain positiiviset ratkaisut kelpaavat. Mahdollisuuksia on siis kaksi. Näitä vastaavat lentoradat ovat

>	radat:= select(x->subs(x, t)>0, juuret);

$\mathrm{radat}:=\left[\left\{\theta =1.369285492,t=99.92514551\right\},\left\{\theta =.1990108389,t=20.40269588\right\}\right]$

>	rata1:= subs(theta=subs(radat[1], theta), lentorata);

$\mathrm{rata1}:=\left[500\cos \left(1.369285492\right)t,-\frac{981}{200}{t}^2+500\sin \left(1.369285492\right)t+25\right]$

>	rata2:= subs(theta=subs(radat[2], theta), lentorata);

$\mathrm{rata2}:=\left[500\cos \left(.1990108389\right)t,-\frac{981}{200}{t}^2+500\sin \left(.1990108389\right)t+25\right]$

Sekunneissa ilmoitetut kokonaislentoajat ovat

>	ajat:= map(x->subs(x, t), radat);

$\mathrm{ajat}:=\left[99.92514551,20.40269588\right]$

Lähtökulmat ovat radiaaneissa. Asteissa ilmoitettuina ne ovat

>	map(x->subs(x, theta), radat): evalf(map(x->convert(x, degrees), %));

$\left[78.45427963\mathrm{degrees},11.40248114\mathrm{degrees}\right]$

Radoista voidaan piirtää kuvaajat ja yhdistää nämä samaan kuvaan:

>	kuva1:= plot([rata1[], t=0..ajat[1]], color=green): kuva1;

>	kuva2:= plot([rata2[], t=0..ajat[2]], color=red): kuva2;

>	with(plots):

Warning, the name changecoords has been redefined

>	display(kuva1, kuva2);

>

Tehtäviä

Määritä ampumaetäisyys lähtökulman funktiona. Piirrä funktion kuvaaja. Millä kulmalla saadaan suurin ampumaetäisyys? Mikä tämä etäisyys on? Kauanko ammuksen lento tällöin kestää?

Miten radan lakikorkeus riippuu lähtökulmasta? Entä ampumaetäisyydestä? Piirrä kuvaajat!

Linkkejä