Tykillä ampuminen 2

Mallinnettaessa heittoliikettä, kuten esimerkiksi tykillä ampumista, keskeisinä vaikuttavina tekijöinä ovat painovoima sekä ilmanvastuksen aiheuttama nopeudelle vastakkaissuuntainen voima.

Painovoima on , missä  on maan vetovoiman aiheuttama kiihtyvyys ja m  heitettävän kappaleen massa. Ilmanvastusvoima on verrannollinen nopeuden neliöön, ja se voidaan mallintaa lausekkeella

missä b  on ilmanvastuskerroin, v  skalaarinen nopeus,  nopeus vektorina ja  nopeuden suuntainen yksikkövektori.

Yleinen liikeyhtälö  saa tällöin muodon

missä on merkitty  sekä .

Tarkastellaan tilannetta, jossa tykillä ammutaan poispäin liikkuvaan maaliin. Mikä on oikea ampumiskulma, kun 25 metrin korkeudella sijaitsevalta tykkilavetilta ammutaan 10 kg kranaatti nopeudella 1000 m/s kohti maalia, jonka etäisyys ampumishetkellä on tasan 5 km? Maali liikkuu 15 m/s tykistä poispäin veden pintaa pitkin, ja ilmanvastuskerroin kranaatille on $b=\frac{1}{10000}$ .

Jaetaan yllä esitetty toisen kertaluvun vektorimuotoinen differentiaaliyhtälö kahteen eri osayhtälöön, z-suuntaan ja x-suuntaan, ja ratkaistaan yhtälöt. Laskujen aluksi on syytä hävittää mahdollisista aiemmista laskuista jääneet muuttujat.

>

restart;

Määritellään differentiaaliyhtälöryhmä  ja sen tuntemattomat muuttujat.

>	ryhma:= m*diff(x(t), t$2)=-b*diff(x(t), t)*sqrt(diff(x(t), t)^2+diff(z(t), t)^2), m*diff(z(t), t$2)=-m*g-b*diff(z(t), t)*sqrt(diff(x(t), t)^2+diff(z(t), t)^2);

$\mathrm{ryhma}:=m\left(\frac{d^2}{{dt}^2}x\left(t\right)\right)=-b\left(\frac{d}{dt}x\left(t\right)\right)\sqrt{\left({\left(\frac{d}{dt}x\left(t\right)\right)}^2+{\left(\frac{d}{dt}z\left(t\right)\right)}^2\right)},m\left(\frac{d^2}{{dt}^2}z\left(t\right)\right)=-mg-b\left(\frac{d}{dt}z\left(t\right)\right)\sqrt{\left({\left(\frac{d}{dt}x\left(t\right)\right)}^2+{\left(\frac{d}{dt}z\left(t\right)\right)}^2\right)}$

>	muuttujat:= x(t), z(t);

$\mathrm{muuttujat}:=x\left(t\right),z\left(t\right)$

Määritellään vakiot ja alkuehto. Ammuksen lähtökulma olkoon $\theta$ . Sisällytetään ehtoon sekä ammuksen alkunopeus jaettuna nopeuskomponentteihin että lähtökorkeus.

>	g:= 9.81: b:= 10^(-4): m:= 10: v0:= 1000:

>	alkuehto:= x(0)=0, z(0)=25, D(x)(0)=v0*cos(theta), D(z)(0)=v0*sin(theta);

$\mathrm{alkuehto}:=x\left(0\right)=0,z\left(0\right)=25,\left(x^{\prime }\right)\left(0\right)=1000\cos \left(\theta \right),\left(z^{\prime }\right)\left(0\right)=1000\sin \left(\theta \right)$

Differentiaaliyhtälöryhmä ei ole ratkaistavissa alkeisfunktioiden avulla, joten ryhmää ei voi ratkaista Maple n avulla $\theta$ :n funktiona. Suljetussa muodossa olevan ratkaisun sijaan joudutaan turvautumaan arvaukseen. Arvataan jokin kulma (radiaaneissa), ja katsotaan, miten hyvin laukaus osui.

>	theta:= 0.03;

$\theta :=.3e-1$

>	rtk1:= dsolve({ryhma, alkuehto}, {muuttujat}, numeric, startinit=true, output=listprocedure);

Poimitaan ratkaisusta x- ja z-suuntia kuvaavat komponentit listaksi ja piirretään kuvio.

>	lentorata1:= subs(rtk1, [x(t), z(t)]):

>	plot([lentorata1[], 0..10]);

Katsotaan miten lähelle laukaus osui. Huomaa, että ratkaisussa on huomioitu myös kohteen liike.

>	lentoaika1:= fsolve(lentorata1[2](t)=0, t=0..10);

$\mathrm{lentoaika1}:=6.811463394$

>	osmaet1:= lentorata1[1](lentoaika1)-(5000+15*lentoaika1);

$\mathrm{osmaet1}:=1484.431854$

Ammus osuu veteen noin puolitoista kilometriä liian kauaksi. Lähtökulma oli siis liian suuri. Arvataan uudestaan tarkoituksena haarukoida oikea tulos arvausten väliin. Tämän jälkeen voidaan systemaattisesti hakea oikea kulma.

>	theta:= 0.01;

$\theta :=.1e-1$

>	rtk2:= dsolve({ryhma,alkuehto}, {muuttujat}, numeric, startinit=true, output=listprocedure);

>	lentorata2:= subs(rtk2, [x(t), z(t)]):

>	lentoaika2:= fsolve(lentorata2[2](t)=0, t=0..10);

$\mathrm{lentoaika2}:=3.499905031$

>	osumaet2:= lentorata2[1](lentoaika2)-(5000+15*lentoaika2);

$\mathrm{osumaet2}:=-1612.618768$

Nyt laukaus jäi liian lyhyeksi. Saimme kuitenkin haarukoitua osumisvälin. Löytääksemme tarkan ampumiskulman, teemme organisoidun kokeilun.

Tehdään pieni for -silmukka, joka tulostaa osumapaikan 21 laskupisteessä 0.001 radiaanin välein. Laskentamenettely hieman poikkeaa edellä olevista, koska Maplen uudemmissa versioissa fsolve-funktio ei kaikissa tapauksissa toimi oikein. Tämän takia käytössä on seuraava erikseen ohjelmoitu proseduuri nollakohta , jossa funktion nollakohdan hakemiseen käytetään regula falsi  -menetelmää.

>	nollakohta:=proc(fkt,x1,x2) local a,b,c,fa,fb: a:=x1: b:=x2: fa:=fkt(a): fb:=fkt(b): if fa*fb>0 then print(FAIL); return end if: c:=(a+b)/2: while abs(a-c)>0.00000001 do a:=c: fa:=fkt(a): c:=a-(a-b)/(fa-fb)*fa: end do: c; end proc:

>

i:= 0: for theta from 0.01 by 0.001 to 0.03 do rtk[i]:= dsolve({ryhma, alkuehto}, {muuttujat}, numeric, startinit=true, output=listprocedure); lentorata:= subs(rtk[i], [x(t), z(t)]); lentoaika:= nollakohta(lentorata[2],0.,10.); osumataul[i]:= lentorata[1](lentoaika)-(5000+15*lentoaika); kulmataul[i]:= theta; i:= i+1; od: kulmat:=[seq(kulmataul[k], k=0..20)]: etaisyydet:= [seq(osumataul[k],k=0..20)];

$\mathrm{etaisyydet}:=\left[-1612.618760,-1475.385567,-1335.351170,-1192.699248,-1047.610328,-900.2601212,-750.8182643,-599.4473395,-446.3022613,-291.5298303,-135.2685688,22.35134319,181.2079169,341.1872060,502.1829512,664.0962402,826.8351781,990.3144468,1154.454953,1319.183384,1484.431852\right]$

Etsitään lähintä osumaa vastaava indeksi ja tämän avulla ampumiskulma, osumaetäisyys ja lentoaika.

>	member(min(map(x->abs(x),etaisyydet)[]),etaisyydet,'ind'): lahin:=[kulmat[ind],etaisyydet[ind]];

$\mathrm{lahin}:=\left[.21e-1,22.35134319\right]$

Sama uudestaan uudella kapeammalla haarukalla ja 0.0001 radiaanin askelvälillä.

>

i:= 0: for theta from 0.020 by 0.0001 to 0.022 do rtk[i]:= dsolve({ryhma, alkuehto}, {muuttujat}, numeric, startinit=true, output=listprocedure); lentorata:= subs(rtk[i], [x(t), z(t)]); lentoaika:= nollakohta(lentorata[2],0.,10.); osumataul[i]:= lentorata[1](lentoaika)-(5000+15*lentoaika); kulmataul[i]:= theta; i:= i+1; od: kulmat:=[seq(kulmataul[k], k=0..20)]: etaisyydet:= [seq(osumataul[k],k=0..20)];

$\mathrm{etaisyydet}:=\left[-135.2685688,-119.5656401,-103.8492586,-88.11954534,-72.37662850,-56.62062526,-40.85166864,-25.06987092,-9.27535822,6.53175518,22.35134319,38.18329350,54.02748394,69.88380224,85.75213014,101.6323504,117.5243548,133.4280249,149.3432505,165.2699182,181.2079169\right]$

>	member(min(map(x->abs(x),etaisyydet)[]),etaisyydet,'ind'): lahin:=[kulmat[ind],etaisyydet[ind]];

$\mathrm{lahin}:=\left[.209e-1,6.53175518\right]$

Osuma on siis runsaan kuuden metrin päässä ja vastaava ampumiskulma on asteissa

>	convert(lahin[1], degrees): evalf(%);

$1.197481792\mathrm{degrees}$

>

>

Tehtäviä

Piirrä lähimmäksi osuvan ammuksen lentorata. Määritä radan lakikorkeus ja ammuksen lentoaika.

Suurenna ilmanvastuskerrointa, ja tutki, miten se vaikuttaa radan muotoon.

Linkkejä

tykillä ampuminen huomioimatta ilmanvastusta

JP & SKK & MS 12.07.2001   & 08.07.2005