Simo K. Kivelä, 13.7.2004

Ääriarvoprobleema

Seuraava tehtävä on vuoden 2000 pitkän matematiikan ylioppilaskokeesta.

Astia on kärjellään seisova avonainen ympyräkartio. Kartion pohjan säde on 6,6 cm ja sivujana 11,0 cm. Astia on täynnä vettä. Astiaan asetetaan pallo, joka sivuaa kartion vaippaa. Määritä pallon säde siten, että astiasta valuva vesimäärä on mahdollisimman suuri.

Ratkaisu laskentaohjelmalla ei periaatteessa eroa kynällä ja paperilla tehdystä ratkaisusta. Eroja kuitenkin on siinä, mihin ratkaisijan on kiinnitettävä huomiota: ohjelmalla laskettassa mekaaniset laskut ovat suhteellisen ongelmattomia, mutta tehtävän rakenne on syytä hahmottaa selkeästi.

Ratkaisu

Numeroarvoista huolimatta laskennassa kannattaa käyttää symboleja mahdollisimman pitkälle. Merkitään seuraavasti:

Kartion pohjan säde r, sivujanan pituus s, korkeus h. Pallon säde R, astiassa olevan pallosegmentin korkeus x, etäisyys kartion kärjestä pallon ja kartion sivuamispisteeseen y.

Symboleilla on seuraavat numeeriset arvot:

numarvot =  {r -> 6.6, s -> 11.0, 
        h -> Sqrt[11.0^2 - 6.6^2]}

Yhdenmuotoisista kolmioista saadaan seuraavat riippuvuudet:

pallonSade =  
      First[Solve[r/s == R/(h - x + R), R]]

sivuamisEtaisyys =  
      First[Solve[R/y == r/h, y]] /. pallonSade

Mallikuvio helpottaa yhdenmuotoisten kolmioiden hahmottamista:

Show[
      Graphics[{Line[{{-r, h}, {0, 0}, {r, h}, {-r, h}}], 
                  Line[{{0, 0}, {0, Max[h, h - x + R]}}], 
                  Line[{{0, h - x + R}, y/s {-r, h}}], PointSize[0.02], 
                  Point[{0, h - x + R}], Circle[{0, h - x + R}, R]} /. 
                pallonSade /. sivuamisEtaisyys /. {x -> 4.5} //. 
          numarvot], AspectRatio -> Automatic]

Astian sisään jäävän pallosegementin tilavuus segmentin korkeuden funktiona on

segmVol =  Pi x^2 (R - x/3) /. pallonSade

Lausekkeen pätevyyttä rajoittaa toisaalta tilanne, missä pallo sivuaa kartiota sen pohjaympyrää pitkin, ja toisaalta tilanne, missä pallo kokonaan sijaitsee kartion sisällä. Näistä saadaan muuttujalle x seuraavat rajat:

x1 =  
      First[Solve[s == (y /. sivuamisEtaisyys), x]] // 
        Simplify

x2 =  
      First[Solve[x == (2 R /. pallonSade), x]] // 
        Simplify

Astiasta poistuva vesimäärä on mahdollisimman suuri, kun kartion sissän jäävän pallosegementin tilavuus on maksimissa. Paikallisten äärarvojen löytämiseksi lasketaan segmentin tilavuuden derivaatta ja sen nollakohdat:

derSegmVol = D[segmVol, x]

nollakohdat =  Solve[derSegmVol == 0, x]

Tässä vaiheessa on luonnollista laskea numeeriset arvot sekä tarkasteluvälille että derivaatan nollakohdille:

numVali = x /. {x1, x2} /. numarvot

numNollat = x /. nollakohdat /. numarvot

Jälkimmäinen nollakohta siis osuu tarkasteluvälille. Maksimiarvot saadaan joko välin päätepisteissä tai derivaatan nollakohdissa. Selkeintä on piirtää funktion kuvaaja:

Plot[
      segmVol /. numarvot, {x, numVali[[1]], 
        numVali[[2]]}]

Maksimiarvo siis todellakin saadaan, kun segmentin korkeus on x  = 4.8 cm. Vastaava pallon säde, pallon tilavuus ja segmentin tilavuus ovat

{R, 4/3 Pi R^3, segmVol} /. pallonSade /. 
        nollakohdat[[2]] /. numarvot

Harjoitustehtäviä

1) Piirrä kuvio tilanteesta, missä pallosegementin tilavuus on suurimmillaan. Piirrä kuviot tarkasteluvälin päätepisteitä vastaavasta tilanteesta.

2) Suorita laskut uudelleen, kun kartion kartion pohjan säde on 5 cm ja sivujanan pituus 20 cm.

3) Tutki, sijaitseeko derivaatan toinen nollakohta aina tarkasteluvälillä riippumatta lukuarvoista, ts. kartion muodosta.

4) Ratkaise tehtävä uudelleen valitsemalla muuttujaksi kartion kärjen ja pallon keskipisteen etäisyys z segmentin korkeuden sijasta. Piirrä myös syrjäytetyn vesimäärän kuvaaja tämän etäisyyden funktiona, kun 0  ≤ z < ∞.