RCL-vihtovirtapiiri: resonanssi

Olkoon tarkastelun kohteena tavallinen RLC-vaihtovirtapiiri. Piirissä on kolme komponenttia, R ohmin vastus, L henryn induktanssi ja C faradin kapasitanssi.

Piiriin syötettyyn jännitteeseen kohdistuu kolme eri pudotusta,

käämin yli,

vastuksen yli, sekä

kondensaattorin yli.

Näiden summasta syntyy piirin Kirchhoffin lain mukainen sähkömotorinen voima E( t ). Mikäli piiriin syötetty jännite on sinimuotoista vaihtovirtaa , saadaan piirille yhtälö

.

Integraalitermistä päästään eroon derivoimalla yhtälö ajan suhteen:

Tämä on differentiaaliyhtälö pakotetulle värähtelylle, jossa ulkoinen pakottava jännite on sinimuotoinen amplitudina .

Jos E ( t )=0, kyseessä vapaa värähtelypiiri ja differentiaaliyhtälö on homogeeninen.

Jos piirissä ei ole vastusta, ts. R = 0, piiri on vaimentamaton. Vastuksen olemassaolo merkitsee, että piirissä on vaimennnus.

Tarkastellaan differentialiyhtälön ratkaisuja vakioiden L , R , C , ja eri arvoilla.

Aluksi hävitetään mahdollisista aiemmista laskuista jääneet muuttujat:

> restart;

Virtaa kuvaava toisen kertaluvun yhtälö.

> yhtalo:= L*diff(i(t), t$2)+R*diff(i(t), t)+1/C*i(t)=omega*E[0]*cos(omega*t);

Vaimentamaton tapaus

Vaimentamattomassa tapauksessa piirissä ei ole vastusta ja yhtälö on

> yhtalo1:= subs(R=0, yhtalo);

Alkuehtona olkoon, että piirissä ei tapahdu mitään:

> alkuehto:= i(0)=0, D(i)(0)=0;

Tämän ratkaisu on

> dsolve({yhtalo1, alkuehto}, i(t)):
ratkaisu1:= subs(%, i(t));

Ratkaisu muodostuu kahdesta kosinitermistä: on peräisin homogeeniyhtälön yleisestä ratkaisusta ja epähomogeeniyhtälön yksittäisratkaisusta. Edellinen kuvaa piirin sisäistä värähtelyä, jälkimmäinen ulkoisen jännitteen taajuudella tapahtuvaa värähtelyä.

Ratkaisu tässä muodossa ei kuitenkaan ole pätevä, jos nimittäjä tulee nollaksi:

> restaajuus:= solve(-1+omega^2*L*C=0, omega);

Nollaksi tuloa vastaavaa pakotteen taajuutta kutsutaan resonanssitaajuudeksi . Tällöin piirin sisäinen värähtelytaajuus ja pakotteen taajuus ovat samat. Kyseessä on tilanne, missä epähomogeenisen yhtälön yksittäisratkaisu saakin erilaisen muodon:

> yhtalo2:= subs(omega=sqrt(C*L)/(C*L), yhtalo1);

> dsolve({yhtalo2, alkuehto}, i(t)):
ratkaisu2:= subs(%,i(t)):
simplify(%);

Tämä on tulkittavissa värähtelytermiksi, jossa virran amplitudi t / (2 L ) kasvaa rajatta muuttujan t mukana. Käytännössä tämä johtaisi piirin palamiseen.

Arvoilla L = 0.1 H , C = 0.001 F, = 230 V saadaan resonanssitaajuudella seuraava kuvio:

> subs({L=0.1, C=0.001, E[0]=230}, ratkaisu2);
plot(%, t = 0..1.5);

Resonanssitaajuus on

> subs({L=0.1, C=0.001}, restaajuus[1]);

Jos pakotteen taajuus on lähellä resonanssitaajuutta, saadaan erikoinen värähtely:

> subs({L=0.1, C=0.001, E[0]=230, omega=90}, ratkaisu1);
plot(%, t = 0..1.5);

Tässä pakote aluksi vahvistaa piirissä kulkevaa virtaa kuten resonanssitaajuuden tapauksessakin, mutta koska taajuudet eivät olekaan täsmälleen samat, värähtelyt siirtyvät vähitellen vastakkaisiin vaiheisiin, ja pakote alkaa sammuttaa piirin virtaa.

Syntynyt värähtely voidaan myös ymmärtää sinivärähtelyksi, jolla on sinimuotoinen vaihteleva amplitudi:

> (cos(100*t)-cos(90*t))-(-2*sin(5*t)*sin(95*t)):
simplify(%);

Vaimennettu tapaus

Yleisen vaimennetun tapauksen ratkaisu on

> yhtalo;

> dsolve(yhtalo, i(t)):
subs(%, i(t)):
ratkaisu:= collect(combine(%), {_C1, _C2, exp});

Ratkaisu koostuu kahdesta termistä:

> sisainen:= select(has, ratkaisu, _C1)+select(has, ratkaisu, _C2);

> ulkoinen:= subs({_C1=0, _C2=0}, ratkaisu);

Sisäisen värähtelyn termi esittää vaimenevaa värähtelyä, sillä muuttujan t kerroin kummassakin eksponentissa on joko negatiivinen reaaliluku tai kompleksiluku, jonka reaaliosa on negatiivinen. Nämä termit siis kuolevat vähitellen pois.

Ulkoisen värähtelyn termi voidaan muokata seuraavasti. Pyritään saattamaan se muotoon, jossa on vain yksi sinifunktio kertoimena sopiva amplitudi A ja argumentissa sopiva vaihesiirto .

> uusimuoto:= expand(A*sin(omega*t+delta));

Vaatimalla että sini- ja kosinitermien kertoimet vanhassa ja uudessa esitysmuodossa ovat samat, saadaan ehdot, joista pyritään ratkaisemaan A ja .

> ehdot:= zip((x, y)->x=y, map2(coeff, ulkoinen, [sin(omega*t), cos(omega*t)]), map2(coeff, uusimuoto, [sin(omega*t), cos(omega*t)])):
simplify(%);

> solve({op(ehdot)}, {A, delta}):
ratk:= allvalues(%);

Pakotteen aiheuttama virta on siis sinimuotoinen amplitudina

> amplitudi:= subs(ratk[1], A);

Amplitudi riippuu pakotteen taajuudesta. Pyritään määrittämään maksimiamplitudi ja vastaava taajuus:

> diff(amplitudi, omega):
derivaatta:= simplify(%);

> maksimikohta:= solve(derivaatta=0, omega);

> subs(omega=sqrt(C*L)/(C*L), amplitudi);
maksimiamplitudi:= simplify(%);

Maple on varovainen yhdistellessään neliöjuuria, ja ainakaan ohjelman versio 6 ei suostunut sieventämään lauseketta pidemmälle. Lauseke on kuitenkin yksinkertainen ja käsin sieventämällä päästään tulokseen . Maksimiarvo saadaan siis resonanssitaajuudella.

Piirretään pakotteen (ulkoisen jännitteen) ja resonanssitaajuutta vastaavan virran kuvaajat:

> numulkoinen:= subs({L=0.1, C=0.0001, R=5, E[0]=230}, ulkoinen);

> jannite:= subs(E[0]=230, E[0]*sin(omega*t));

> res:= subs({L=0.1, C=0.0001, R=5, E[0]=230},1/sqrt(L*C));

> plot(subs(omega=res, {jannite, numulkoinen}),t=0..0.1);

Kuviossa on jännite punaisella ja virta vihreällä.

Vastaava kuvio, kun kyseessä ei ole resonanssitaajuus:

> plot(subs(omega=280, {jannite, numulkoinen}), t=0..0.1);

Tehtäviä

Tutki, miten alkuehtojen muuttaminen vaikuttaa ratkaisuun vaimentamattomassa tapauksessa. Miten ratkaisun luonne muuttuu, kun ollaan resonanssikohdan lähellä?

Piirrä kuvaaja, joka esittää vaimennetun tapauksen virtaa pakotteen taajuuden funktiona. Onko vaimennetun piirin tapauksessa sellainen ratkaisu mahdollinen, jossa virran amplitudi rajatta kasvaa, ts. piiri palaa?